(VBScript) Duplicate openssl pkcs12 –export –in certfile.cer –inkey certfile.key –out certfile.pfx

How to create a PKCS12 (.p12 or .pfx) from a certificate file and private key file: Demonstrates how to duplicate this OpenSSL command:

Duplicate openssl pkcs12 –export –in certfile.cer –inkey certfile.key –out certfile.pfx

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PrivateKey")
set pkey = CreateObject("Chilkat.PrivateKey")

' Load the private key from the file.
success = pkey.LoadAnyFormatFile("certFile.key","")
If (success <> 1) Then
    outFile.WriteLine(pkey.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
' The LoadFromFile method auto-recognizes the format...
success = cert.LoadFromFile("certfile.cer")
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' We'll need a cert chain object to create the PKCS12, so get it
' from the cert.  

' certChain is a Chilkat.CertChain
Set certChain = cert.GetCertChain()
If (Not cert.LastMethodSuccess) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Create the PFX object, add the cert and private key, and write to a .pfx file.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Pfx")
set pfx = CreateObject("Chilkat.Pfx")

' The cert(s) are automatically added in the call to AddPrivateKey
success = pfx.AddPrivateKey(pkey,certChain)
If (success <> 1) Then
    outFile.WriteLine(pfx.LastErrorText)
    WScript.Quit
End If

' Write the .pfx to a file.
password = "myPassword"
success = pfx.ToFile(password,"certfile.pfx")
If (success <> 1) Then
    outFile.WriteLine(pfx.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close