VBScript

OpenAI (ChatGPT) Create Chat Completion

See more OpenAI ChatGPT Examples

Shows how to create a model response for a given chat conversation. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' Implements the following CURL command:

' curl https://api.openai.com/v1/chat/completions \
'   -H "Content-Type: application/json" \
'   -H "Authorization: Bearer $OPENAI_API_KEY" \
'   -d '{
'     "model": "gpt-3.5-turbo",
'     "messages": [{"role": "user", "content": "Hello!"}]
'   }'

' Use the following online tool to generate HTTP code from a CURL command
' Convert a cURL Command to HTTP Source Code

' Use this online tool to generate code from sample JSON:
' Generate Code to Create JSON

' The following JSON is sent in the request body.

' {
'   "model": "gpt-3.5-turbo",
'   "messages": [
'     {
'       "role": "user",
'       "content": "Hello!"
'     }
'   ]
' }

set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("model","gpt-3.5-turbo")
success = json.UpdateString("messages[0].role","user")
success = json.UpdateString("messages[0].content","Hello!")

' Adds the "Authorization: Bearer $OPENAI_API_KEY" header.
' This is NOT a real key.  Change the "sk-vi...." to your own key.
http.AuthToken = "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"
http.SetRequestHeader "Content-Type","application/json"

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpJson("POST","https://api.openai.com/v1/chat/completions",json,"application/json",resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

set sbResponseBody = CreateObject("Chilkat.StringBuilder")
success = resp.GetBodySb(sbResponseBody)

set jResp = CreateObject("Chilkat.JsonObject")
success = jResp.LoadSb(sbResponseBody)
jResp.EmitCompact = 0

outFile.WriteLine("Response Body:")
outFile.WriteLine(jResp.Emit())

respStatusCode = resp.StatusCode
outFile.WriteLine("Response Status Code = " & respStatusCode)
If (respStatusCode >= 400) Then
    outFile.WriteLine("Response Header:")
    outFile.WriteLine(resp.Header)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' Sample JSON response:
' (Sample code for parsing the JSON response is shown below)

' {
'   "id": "chatcmpl-123",
'   "object": "chat.completion",
'   "created": 1677652288,
'   "choices": [
'     {
'       "index": 0,
'       "message": {
'         "role": "assistant",
'         "content": "\n\nHello there, how may I assist you today?"
'       },
'       "finish_reason": "stop"
'     }
'   ],
'   "usage": {
'     "prompt_tokens": 9,
'     "completion_tokens": 12,
'     "total_tokens": 21
'   }
' }

' Sample code for parsing the JSON response...
' Use the following online tool to generate parsing code from sample JSON:
' Generate Parsing Code from JSON

id = jResp.StringOf("id")
v_object = jResp.StringOf("object")
created = jResp.IntOf("created")
Prompt_tokens = jResp.IntOf("usage.prompt_tokens")
Completion_tokens = jResp.IntOf("usage.completion_tokens")
Total_tokens = jResp.IntOf("usage.total_tokens")
i = 0
count_i = jResp.SizeOfArray("choices")
Do While i < count_i
    jResp.I = i
    index = jResp.IntOf("choices[i].index")
    Role = jResp.StringOf("choices[i].message.role")
    Content = jResp.StringOf("choices[i].message.content")
    finish_reason = jResp.StringOf("choices[i].finish_reason")
    i = i + 1
Loop

outFile.Close