VBScript
OneNote - Get Page HTML Content

Download the HTML content of a OneNote page. Also iterates over the images and attachments on the OneNote page and downloads the content for each.
Chilkat VBScript Downloads

Download Chilkat for VBScript
VBScript
Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

' Implements the following CURL command:

' curl -X GET https://graph.microsoft.com/v1.0/me/onenote/pages/{id}/content?includeIDs=true \
'   -H 'authorization: Bearer ACCESS_TOKEN'

' Use the following online tool to generate HTTP code from a CURL command
' Convert a cURL Command to HTTP Source Code

' Adds the "Authorization: Bearer ACCESS_TOKEN" header.
http.AuthToken = "ACCESS_TOKEN"

success = http.SetUrlVar("page_id","0-d2298668edd74dccac7f821fa378bf64!41-3A33FCEB9B74CC15!20350")

set sbResponseBody = CreateObject("Chilkat.StringBuilder")
success = http.QuickGetSb("https://graph.microsoft.com/v1.0/me/onenote/pages/{$page_id}/content?includeIDs=true",sbResponseBody)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("HTML content:")
outFile.WriteLine(sbResponseBody.GetAsString())

respStatusCode = http.LastStatus
outFile.WriteLine("Response Status Code = " & respStatusCode)
If (respStatusCode >= 400) Then
    outFile.WriteLine("Response Header:")
    outFile.WriteLine(http.LastHeader)
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' Let's get the images and attached files.
' Here's sample HTML content with 2 images and one PDF attachment:

' <html lang="en-US">
' 	<head>
' 		<title>A page with rendered images and an attached file</title>
' 		<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
' 		<meta name="created" content="2020-10-23T12:00:00.0000000" />
' 	</head>
' 	<body data-absolute-enabled="true" style="font-family:Calibri;font-size:11pt">
' 		<div id="div:{b130eb6c-638a-4f97-8f7e-b6d9e2e88bf9}{32}" data-id="_default" style="position:absolute;left:48px;top:120px;width:624px">
' 			<p id="p:{b130eb6c-638a-4f97-8f7e-b6d9e2e88bf9}{39}" style="margin-top:5.5pt;margin-bottom:5.5pt">Here&#39;s an image from an online source:</p>
' 			<img id="img:{ee18fe8d-b219-4baf-9b4d-4fc680579f0d}{1}" alt="an image on the page" width="500" height="500" src="https://graph.microsoft.com/v1.0/users('admin@chilkat.io')/onenote/resources/0-e71b45b763484921b4200e32c2439a47!1-3A33FCEB9B74CC15!20350/$value" data-src-type="image/jpeg" data-fullres-src="https://graph.microsoft.com/v1.0/users('admin@chilkat.io')/onenote/resources/0-e71b45b763484921b4200e32c2439a47!1-3A33FCEB9B74CC15!20350/$value" data-fullres-src-type="image/jpeg" />
' 			<p id="p:{b130eb6c-638a-4f97-8f7e-b6d9e2e88bf9}{43}" style="margin-top:5.5pt;margin-bottom:5.5pt">Here&#39;s an image uploaded as binary data:</p>
' 			<img id="img:{ee18fe8d-b219-4baf-9b4d-4fc680579f0d}{3}" alt="an image on the page" width="300" height="225" src="https://graph.microsoft.com/v1.0/users('admin@chilkat.io')/onenote/resources/0-a60516b962b842f2ae9bec75c16b31de!1-3A33FCEB9B74CC15!20350/$value" data-src-type="image/jpeg" data-fullres-src="https://graph.microsoft.com/v1.0/users('admin@chilkat.io')/onenote/resources/0-a60516b962b842f2ae9bec75c16b31de!1-3A33FCEB9B74CC15!20350/$value" data-fullres-src-type="image/jpeg" />
' 			<p id="p:{b130eb6c-638a-4f97-8f7e-b6d9e2e88bf9}{47}" style="margin-top:5.5pt;margin-bottom:5.5pt">Here&#39;s a file attachment:</p>
' 			<object data-attachment="FileName.pdf" type="application/pdf" data="https://graph.microsoft.com/v1.0/users('admin@chilkat.io')/onenote/resources/0-9e685efb33a24a6a8de1b9c707d28385!1-3A33FCEB9B74CC15!20350/$value" />
' 		</div>
' 	</body>
' </html>

set xml = CreateObject("Chilkat.Xml")
success = xml.LoadSb(sbResponseBody,1)

' Iterate over each element in the XML.  Each time we find an "img" or "object", download the data.
' (The sbState is an object used to keep track of the current state of the traversal.)
set sbState = CreateObject("Chilkat.StringBuilder")

set bd = CreateObject("Chilkat.BinData")
Do While xml.NextInTraversal2(sbState) <> 0

    If (xml.TagEquals("img") = 1) Then
        outFile.WriteLine("img id: " & xml.GetAttrValue("id"))
        url = xml.GetAttrValue("src")
        success = bd.Clear()
        success = http.QuickGetBd(url,bd)
        If (success = 0) Then
            outFile.WriteLine(http.LastErrorText)
            WScript.Quit
        End If

        outFile.WriteLine("Downloaded from " & url)
        outFile.WriteLine("----")
        ' If desired, bd.WriteFile to save the contents of bd to a file..
    End If

    If (xml.TagEquals("object") = 1) Then
        outFile.WriteLine("data-attachment: " & xml.GetAttrValue("data-attachment"))
        outFile.WriteLine("type: " & xml.GetAttrValue("type"))
        url = xml.GetAttrValue("data")
        success = bd.Clear()
        success = http.QuickGetBd(url,bd)
        If (success = 0) Then
            outFile.WriteLine(http.LastErrorText)
            WScript.Quit
        End If

        outFile.WriteLine("Downloaded from " & url)
        outFile.WriteLine("----")
        ' If desired, bd.WriteFile to save the contents of bd to a file..
    End If

Loop

outFile.WriteLine("Success.")

outFile.Close