(VBScript) Office365 IMAP OAuth2 with Shared Mailbox

See more Office365 Examples

Demonstrates how to authenticate using OAuth2 with shared mailboxes in outlook.office365.com. (SASL XOAUTH2 authentication for shared mailboxes in Office 365)

For more information, see https://docs.microsoft.com/en-us/exchange/client-developer/legacy-protocols/how-to-authenticate-an-imap-pop-smtp-application-by-using-oauth#sasl-xoauth2-authentication-for-shared-mailboxes-in-office-365

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' An Office365 OAuth2 access token must first be obtained prior
' to running this code.

' Getting the OAuth2 access token for the 1st time requires the O365 account owner's 
' interactive authorizaition via a web browser.  Afterwards, the access token
' can be repeatedly refreshed automatically.

' See the following examples for getting and refreshing an OAuth2 access token

' Get Office365 SMTP/IMAP/POP3 OAuth2 Access Token
' Refresh Office365 SMTP/IMAP/POP3 OAuth2 Access Token

' First get our previously obtained OAuth2 access token.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonToken = CreateObject("Chilkat.JsonObject")
success = jsonToken.LoadFile("qa_data/tokens/office365.json")
If (success = 0) Then
    outFile.WriteLine("Failed to open the office365 OAuth JSON file.")
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Imap")
set imap = CreateObject("Chilkat.Imap")

imap.Ssl = 1
imap.Port = 993

' Connect to the Office365 IMAP server.
success = imap.Connect("outlook.office365.com")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Use OAuth2 authentication.
imap.AuthMethod = "XOAUTH2"

' In case of shared mailbox access using OAuth, application needs to obtain the access token on behalf of a user
' but replace the userName field in the SASL XOAUTH2 encoded string with the email address of the shared mailbox.

' Login using the shared mailbox email address for the username, and the access token for the password.
' This will cause the SASL XOAUTH2 format to be used, as described at Office 365 SASL XOAUTH2 format 

success = imap.Login("SHARED_MAILBOX_EMAIL_ADDRESS",jsonToken.StringOf("access_token"))
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("O365 OAuth2 shared mailbox authentication is successful.")

' Do something...
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Your application can continue to do other things in the IMAP session....

' When finished, logout and close the connection.
success = imap.Logout()
success = imap.Disconnect()

outFile.WriteLine("Finished.")

outFile.Close