(VBScript) Hungary NAV Token Exchange

Demonstrates the tokenExchange request for the Hungarian NAV Online Invoicing System REST API v2.0.

Note: This example requires Chilkat v9.5.0.83 or greater.

For more information, see https://onlineszamla.nav.gov.hu/api/files/container/download/Online%20Szamla_Interfesz%20specifik%C3%A1ci%C3%B3_EN_v2.0.pdf

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Build the following XML:

' Use this online tool to generate code from sample XML: 
' Generate Code to Create XML

' <?xml version="1.0" encoding="UTF-8"?>
' <TokenExchangeRequest xmlns="http://schemas.nav.gov.hu/OSA/2.0/api">
' 	<header>
' 		<requestId>RID896801578348</requestId>
' 		<timestamp>2019-09-11T10:55:31.440Z</timestamp>
' 		<requestVersion>2.0</requestVersion>
' 		<headerVersion>1.0</headerVersion>
' 	</header>
' 	<user>
' 		<login>lwilsmn0uqdxe6u</login>
' 		<passwordHash>2F43840A882CFDB7DB0FEC07D419D030D864B47B6B541DC280EF81B937B7A176E33C052B0D26638CC18A7A2C08D8D311733078A774BF43F6CA57FE8CD74DC28E</passwordHash>
' 		<taxNumber>11111111</taxNumber>
' 		<requestSignature>B4B5E0F197BFFD3DF69BCC98D3BE775F65FD5445EEF95C9D6B6C59425F2B81C4F6DA1FD563B0C7E7D98AF1E1725E5C63C2803B5D3A93D1C02ED354AC92F2CC94</requestSignature>
' 		<!--<signKey>ac-ac3a-7f661bff7d342N43CYX4U9FG</signKey>-->
' 	</user>
' 	<software>
' 		<softwareId>123456789123456789</softwareId>
' 		<softwareName>string</softwareName>
' 		<softwareOperation>LOCAL_SOFTWARE</softwareOperation>
' 		<softwareMainVersion>string</softwareMainVersion>
' 		<softwareDevName>string</softwareDevName>
' 		<softwareDevContact>string</softwareDevContact>
' 		<softwareDevCountryCode>HU</softwareDevCountryCode>
' 		<softwareDevTaxNumber>string</softwareDevTaxNumber>
' 	</software>
' </TokenExchangeRequest>

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.CkDateTime")
set dtNow = CreateObject("Chilkat.CkDateTime")
success = dtNow.SetFromCurrentSystemTime()
outFile.WriteLine(dtNow.GetAsTimestamp(0))

' The hash algorithm for the password is SHA512 (not SHA3-512).
crypt.HashAlgorithm = "sha512"
crypt.EncodingMode = "hex"
myPassword = "my-password"
passwordHash = crypt.HashStringENC(myPassword)

' Generate a random request ID like "RID215118906689"
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Prng")
set prng = CreateObject("Chilkat.Prng")
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbRequestId = CreateObject("Chilkat.StringBuilder")
success = sbRequestId.Append("RID")
success = sbRequestId.Append(prng.RandomString(12,1,0,0))
outFile.WriteLine("generated requestId = " & sbRequestId.GetAsString())

' IMPORTANT: This example requires Chilkat v9.5.0.83 or greater.  The SHA3 hash algorithm is implemented in Chilkat v9.5.0.83, but not in earlier versions.
' IMPORTANT: This example requires Chilkat v9.5.0.83 or greater.  The SHA3 hash algorithm is implemented in Chilkat v9.5.0.83, but not in earlier versions.
' IMPORTANT: This example requires Chilkat v9.5.0.83 or greater.  The SHA3 hash algorithm is implemented in Chilkat v9.5.0.83, but not in earlier versions.
' IMPORTANT: This example requires Chilkat v9.5.0.83 or greater.  The SHA3 hash algorithm is implemented in Chilkat v9.5.0.83, but not in earlier versions.
' IMPORTANT: This example requires Chilkat v9.5.0.83 or greater.  The SHA3 hash algorithm is implemented in Chilkat v9.5.0.83, but not in earlier versions.
' Calculate the requestSignature
crypt.HashAlgorithm = "sha3-512"
signatureKey = "ce-8f5e-215119fa7dd621DLMRHRLH2S"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbFinalHashBase = CreateObject("Chilkat.StringBuilder")

' First append the timestamp because we are going to remove certain chars/parts.
success = sbFinalHashBase.Append(dtNow.GetAsTimestamp(0))
numReplaced = sbFinalHashBase.Replace("Z","")
numReplaced = sbFinalHashBase.Replace("-","")
numReplaced = sbFinalHashBase.Replace(":","")
numReplaced = sbFinalHashBase.Replace("T","")

' Prepend the requestId and append the signatureKey
success = sbFinalHashBase.Prepend(sbRequestId.GetAsString())
success = sbFinalHashBase.Append(signatureKey)

requestSignature = crypt.HashStringENC(sbFinalHashBase.GetAsString())

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xml = CreateObject("Chilkat.Xml")
xml.Tag = "TokenExchangeRequest"
success = xml.AddAttribute("xmlns","http://schemas.nav.gov.hu/OSA/2.0/api")
xml.UpdateChildContent "header|requestId",sbRequestId.GetAsString()
xml.UpdateChildContent "header|timestamp",dtNow.GetAsTimestamp(0)
xml.UpdateChildContent "header|requestVersion","2.0"
xml.UpdateChildContent "header|headerVersion","1.0"
xml.UpdateChildContent "user|login","lwilsmn0uqdxe6u"
xml.UpdateChildContent "user|passwordHash",passwordHash
xml.UpdateChildContent "user|taxNumber","11111111"
xml.UpdateChildContent "user|requestSignature",requestSignature
xml.UpdateChildContent "software|softwareId","123456789123456789"
xml.UpdateChildContent "software|softwareName","string"
xml.UpdateChildContent "software|softwareOperation","LOCAL_SOFTWARE"
xml.UpdateChildContent "software|softwareMainVersion","string"
xml.UpdateChildContent "software|softwareDevName","string"
xml.UpdateChildContent "software|softwareDevContact","string"
xml.UpdateChildContent "software|softwareDevCountryCode","HU"
xml.UpdateChildContent "software|softwareDevTaxNumber","string"

' POST the XML to https://api-test.onlineszamla.nav.gov.hu/invoiceService/v2/tokenExchange
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")
http.Accept = "application/xml"
http.SetRequestHeader "Content-Type","application/xml"
endpoint = "https://api-test.onlineszamla.nav.gov.hu/invoiceService/v2/tokenExchange"
' resp is a Chilkat.HttpResponse
Set resp = http.PostXml(endpoint,xml.GetXml(),"utf-8")
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response status code = " & resp.StatusCode)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set respXml = CreateObject("Chilkat.Xml")
success = respXml.LoadXml(resp.BodyStr)
outFile.WriteLine("Response body:")
outFile.WriteLine(respXml.GetXml())

' Save our exchange token to a file to be used for subsequent requests.
success = respXml.SaveXml("qa_data/tokens/nav_exchange_token.xml")

' The result looks like this:

' <?xml version="1.0" encoding="UTF-8" standalone="yes"?>
' <TokenExchangeResponse xmlns="http://schemas.nav.gov.hu/OSA/2.0/api" xmlns:ns2="http://schemas.nav.gov.hu/OSA/2.0/data">
'     <header>
'         <requestId>RID789246611489</requestId>
'         <timestamp>2020-03-25T14:14:36Z</timestamp>
'         <requestVersion>2.0</requestVersion>
'         <headerVersion>1.0</headerVersion>
'     </header>
'     <result>
'         <funcCode>OK</funcCode>
'     </result>
'     <software>
'         <softwareId>123456789123456789</softwareId>
'         <softwareName>string</softwareName>
'         <softwareOperation>LOCAL_SOFTWARE</softwareOperation>
'         <softwareMainVersion>string</softwareMainVersion>
'         <softwareDevName>string</softwareDevName>
'         <softwareDevContact>string</softwareDevContact>
'         <softwareDevCountryCode>HU</softwareDevCountryCode>
'         <softwareDevTaxNumber>string</softwareDevTaxNumber>
'     </software>
'     <encodedExchangeToken>2lR5v57Tl ... 9n4tIWCYgjKQ==</encodedExchangeToken>
'     <tokenValidityFrom>2020-03-25T15:14:36.987+01:00</tokenValidityFrom>
'     <tokenValidityTo>2020-03-25T15:19:36.987+01:00</tokenValidityTo>
' </TokenExchangeResponse>

' Use this online tool to generate parsing code from sample XML: 
' Generate Parsing Code from XML

TokenExchangeResponse_xmlns = respXml.GetAttrValue("xmlns")
TokenExchangeResponse_xmlns_ns2 = respXml.GetAttrValue("xmlns:ns2")
requestId = respXml.GetChildContent("header|requestId")
timestamp = respXml.GetChildContent("header|timestamp")
requestVersion = respXml.GetChildContent("header|requestVersion")
headerVersion = respXml.GetChildContent("header|headerVersion")
funcCode = respXml.GetChildContent("result|funcCode")
softwareId = respXml.GetChildContent("software|softwareId")
softwareName = respXml.GetChildContent("software|softwareName")
softwareOperation = respXml.GetChildContent("software|softwareOperation")
softwareMainVersion = respXml.GetChildContent("software|softwareMainVersion")
softwareDevName = respXml.GetChildContent("software|softwareDevName")
softwareDevContact = respXml.GetChildContent("software|softwareDevContact")
softwareDevCountryCode = respXml.GetChildContent("software|softwareDevCountryCode")
softwareDevTaxNumber = respXml.GetChildContent("software|softwareDevTaxNumber")
encodedExchangeToken = respXml.GetChildContent("encodedExchangeToken")
tokenValidityFrom = respXml.GetChildContent("tokenValidityFrom")
tokenValidityTo = respXml.GetChildContent("tokenValidityTo")

outFile.Close