(VBScript) MyInvois Malaysia Submit Document

See more Malaysia MyInvois Examples

Demonstrates how to submit a document to MyInvois.

For more information, see https://sdk.myinvois.hasil.gov.my/einvoicingapi/02-submit-documents/

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' The following JSON is sent in the request body.

' {
'   "documents": [
'     {
'       "format": "XML",
'       "documentHash": "<SHA256_hash_of_document>",
'       "codeNumber": "INV12345",
'       "document": "<Document_encoded_in_Base64>"
'     }
'   ]
' }

' Load the document to be sent.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbXmlDoc = CreateObject("Chilkat.StringBuilder")
success = sbXmlDoc.LoadFile("c:/invoices/invoice1.xml","utf-8")

' The MyInvois online documentation neglects to tell us the encoding of the documentHash.
' Should it be base64?  Or hex?  We can only guess.  MyInvois provides no samples,
' and omits these crucial details which are needed for actual implementation.
' 
' *** Note: It was confirmed that "hex" is the encoding that is needed.
sha256 = sbXmlDoc.GetHash("sha256","hex","utf-8")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbEncoded = CreateObject("Chilkat.StringBuilder")
success = sbEncoded.AppendSb(sbXmlDoc)
success = sbEncoded.Encode("base64","utf-8")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("documents[0].format","XML")
success = json.UpdateString("documents[0].documentHash",sha256)
success = json.UpdateString("documents[0].codeNumber","INV12345")
success = json.UpdateSb("documents[0].document",sbEncoded)

' Adds the "Authorization: Bearer <access_token>" header.
http.AuthToken = "<access_token>"

' resp is a Chilkat.HttpResponse
Set resp = http.PostJson3("https://preprod-api.myinvois.hasil.gov.my/api/v1.0/documentsubmissions","application/json",json)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("response status code = " & resp.StatusCode)
outFile.WriteLine(resp.BodyStr)


outFile.Close