(VBScript) MyInvois Malaysia Login as Intermediary System

See more Malaysia MyInvois Examples

Demonstrates how to get an OAuth2 access token with an intermediary that is representing a taxpayer (acting on behalf of a specific taxpayer). The OAuth2 access token can then be used to access MyInvois protected APIs.

For more information, see https://sdk.myinvois.hasil.gov.my/api/08-login-as-intermediary-system/

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Sends the following HTTP POST to get a MyInvois OAUth2 access token using client_credentials

' POST /connect/token HTTP/1.1
' Host: preprod-api.myinvois.hasil.gov.my
' Accept: */*
' Content-Length: <<variable>>
' Content-Type: application/x-www-form-urlencoded
' 
' client_id={YOUR_CLIENT_ID}&client_secret={YOUR_CLIENT_SECRET}&grant_type=client_credentials&scope=InvoicingAPI

' --------------------------------------------------------------------------------------------------------
' Note: There is a large amount of information about the MyInvois API on the Internet.
' The information is found at https://sdk.myinvois.hasil.gov.my/
' and also at many other companies offering solutions.
' 
' Unfortunately, it's all completely useless to the programmer wishing to implement the API.
' The reason it's useless is because no specifics are given.
' A developer needs to know the specific details of the HTTP request and response.
' What is the HTTP request Content-Type?
' What is the endpoint?
' What is the format of request body and response?  JSON or XML?
' What specific header fields are needed, if any?
' 
' Providing samples of raw HTTP requests and responses tells the developer everything he/she needs to know.
' All unknowns become known.  
' Everything becomes easy to implement.
' Just show some sample raw HTTP requests and responses, and we can all spend far less time in the office
' and more time relaxing on a beach.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = CreateObject("Chilkat.HttpRequest")
req.AddParam "grant_type","client_credentials"
req.AddParam "client_id","YOUR_CLIENT_ID"
req.AddParam "client_secret","YOUR_CLIENT_SECRET"
req.AddParam "scope","InvoicingAPI"

' resp is a Chilkat.HttpResponse
Set resp = http.PostUrlEncoded("https://preprod-api.myinvois.hasil.gov.my/connect/token",req)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Note: The returned access token is valid for a short amount of time.  Perhaps 1 hour.
' The access token is used in the "Authorization: Bearer <access_token>" header in subsequent requests until it expires.
' Your application would then need to get a new access token, and so on..

outFile.WriteLine("Response Status Code: " & resp.StatusCode)
outFile.WriteLine("Response Body:")
outFile.WriteLine(resp.BodyStr)

' Here's a sample response:

' {
'   "access_token": "eyJhbGciOiJSUzI1...",
'   "expires_in": 3600,
'   "token_type": "Bearer",
'   "scope": "InvoicingAPI"
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(resp.BodyStr)
access_token = json.StringOf("access_token")
expires_in = json.IntOf("expires_in")
token_type = json.StringOf("token_type")
scope = json.StringOf("scope")

' To use an access token in a MyInvois API call, see Using a MyInvois Access Token in an API Request

outFile.Close