(VBScript) Add Data to multipart/form-data Request

Demonstrates how to add content (such as a JPG, PDF, XML, etc.) to multipart/form-data requests.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = CreateObject("Chilkat.HttpRequest")
req.HttpVerb = "POST"
req.ContentType = "multipart/form-data"
req.Path = "/xyz/something"

req.AddParam "param1","value1"
req.AddParam "param2","value2"

' Add some small files to the request. (Small so we can see what the full request looks like without too much data..)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.BinData")
set bd = CreateObject("Chilkat.BinData")
success = bd.LoadFile("qa_data/jpg/starfish20.jpg")
success = req.AddBdForUpload("starfish20","starfish20.jpg",bd,"image/jpeg")

success = bd.LoadFile("qa_data/pdf/helloWorld.pdf")
success = req.AddBdForUpload("helloWorld","helloWorld.pdf",bd,"application/pdf")

success = bd.LoadFile("qa_data/xml/tinyA.xml")
success = req.AddBdForUpload("tinyA","tinyA.xml",bd,"text/xml")

' This HTTP request contains binary data, so we cannot call GenerateRequestText
' to examine it as a string.  We can instead call GenerateRequestFile
' to write the request to a file and then examine using a hex editor,
' or an editor that is capable of handling null bytes and non-printable chars (perhaps by displaying "?" chars instead).
success = req.GenerateRequestFile("qa_output/multipartFormDataRequest.bin")

outFile.WriteLine("OK.")

' This is the HTTP multipart/form-data request built by the above code:

' POST /xyz/something HTTP/1.1
' Host: domain
' Content-Type: multipart/form-data; boundary=------------090708030009010000030901
' Content-Length: 2220
' 
' --------------090708030009010000030901
' Content-Disposition: form-data; name="param1"
' 
' value1
' --------------090708030009010000030901
' Content-Disposition: form-data; name="param2"
' 
' value2
' --------------090708030009010000030901
' Content-Disposition: form-data; name="starfish20"; filename="starfish20.jpg"
' Content-Type: image/jpeg
' 
' JPEG DATA HERE...
' --------------090708030009010000030901
' Content-Disposition: form-data; name="helloWorld"; filename="helloWorld.pdf"
' Content-Type: application/pdf
' 
' PDF DATA HERE...
' --------------090708030009010000030901
' Content-Disposition: form-data; name="tinyA"; filename="tinyA.xml"
' Content-Type: text/xml
' 
' XML DATA HERE...
' --------------090708030009010000030901--
' 

outFile.Close