(VBScript) SOAP with MTOM XOP 8bit (binary) Attachment

Demonstrates how to send the following sample SOAP request with an MTOM/XOP attachment:

Content-Type: Multipart/Related; start-info="text/xml"; type="application/xop+xml"; boundary="----=_Part_0_1744155.1118953559416"
Content-Length: 3453
SOAPAction: "some-SOAP-action"

------=_Part_1_4558657.1118953559446
Content-Type: application/xop+xml; type="text/xml"; charset=utf-8

<soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/">
  <soap:Body>
    <Detail xmlns="http://example.org/mtom/data">
      <image>
        <xop:Include xmlns:xop="http://www.w3.org/2004/08/xop/include" href="cid:5aeaa450-17f0-4484-b845-a8480c363444@example.org" />
      </image>
    </Detail>
  </soap:Body>
</soap:Envelope>

------=_Part_1_4558657.1118953559446
Content-Type: image/jpeg
Content-ID: _LT_5aeaa450-17f0-4484-b845-a8480c363444@example.org_GT_
Content-Disposition: 8bit

... binary data ...

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set soapXml = CreateObject("Chilkat.Xml")

soapXml.Tag = "soap:Envelope"
success = soapXml.AddAttribute("xmlns:soap","http://schemas.xmlsoap.org/soap/envelope/")

soapXml.NewChild2 "soap:Body",""
success = soapXml.GetChild2(0)

soapXml.NewChild2 "Detail",""
success = soapXml.GetChild2(0)
success = soapXml.AddAttribute("xmlns","http://example.org/mtom/data")

soapXml.NewChild2 "image",""
success = soapXml.GetChild2(0)

soapXml.NewChild2 "xop:Include",""
success = soapXml.GetChild2(0)
success = soapXml.AddAttribute("xmlns:xop","http://www.w3.org/2004/08/xop/include")
success = soapXml.AddAttribute("href","cid:5aeaa450-17f0-4484-b845-a8480c363444@example.org")

soapXml.GetRoot2 
soapXml.EmitXmlDecl = 0

xmlBody = soapXml.GetXml()
outFile.WriteLine(xmlBody)

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.HttpRequest")
set req = CreateObject("Chilkat.HttpRequest")
req.HttpVerb = "POST"
req.Path = "/something/someTarget"

req.ContentType = "multipart/related; start-info=""text/xml""; type=""application/xop+xml"""
req.AddHeader "SOAPAction","some-SOAP-action"

success = req.AddStringForUpload2("","",xmlBody,"utf-8","application/xop+xml; type=""text/xml""; charset=utf-8")

' The bytes will be sent as binary (not base64 encoded).
success = req.AddFileForUpload2("","qa_data/jpg/starfish.jpg","image/jpeg")

' The JPEG data is the 2nd sub-part, and therefore is at index 1 (the first sub-part is at index 0)
success = req.AddSubHeader(1,"Content-ID","<5aeaa450-17f0-4484-b845-a8480c363444@example.org>")

' Add the Content-Disposition: 8bit sub-header
success = req.AddSubHeader(1,"Content-Disposition","8bit")

http.FollowRedirects = 1

' For debugging, set the SessionLogFilename property
' to see the exact HTTP request and response in a log file.
' (Given that the request contains binary data, you'll need an editor
' that can gracefully view text + binary data.  I use EmEditor for most simple editing tasks..)
http.SessionLogFilename = "qa_output/mtom_sessionLog.txt"

useTls = 1
' Note: Please don't run this example without changing the domain to your own domain...
' resp is a Chilkat.HttpResponse
Set resp = http.SynchronousRequest("www.example.org",443,useTls,req)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Xml")
set xmlResponse = CreateObject("Chilkat.Xml")
success = xmlResponse.LoadXml(resp.BodyStr)
outFile.WriteLine(xmlResponse.GetXml())


outFile.Close