(VBScript) MS Teamwork: Update an Online Meeting

See more Microsoft Teams Examples

Demonstrates how to update a Microsoft Teamwork Online Meeting

Note:If using Application access (i.e. client credentials) which is what this example is doing, then you'll need to "Configure application access to online meetings or virtual events" See https://learn.microsoft.com/en-us/graph/cloud-communication-online-meeting-application-access-policy#configure-application-access-policy

For example, here's our Powershell session to setup the policy.

Windows PowerShell
Copyright (C) Microsoft Corporation. All rights reserved.
Try the new cross-platform PowerShell
https://aka.ms/pscore6 

PS C:\WINDOWS\system32> Install-Module -Name PowerShellGet -Force -AllowClobber
PS C:\WINDOWS\system32> Install-Module -Name MicrosoftTeams -Force -AllowClobber
PS C:\WINDOWS\system32> Connect-MicrosoftTeams

Account              Environment Tenant                               TenantId
-------              ----------- ------                               --------
admin@chilkat365.com AzureCloud  112d7ed6-71bf-4eba-a866-738364321bfc 112d7ed6-71bf-4eba-a866-738364321bfc

PS C:\WINDOWS\system32> New-CsApplicationAccessPolicy -Identity Test-Teams-policy -AppIds "e1cd2318-298b-4916-bfd6-78cae9938835" -Description "Want App to be able to work with Teams for a User"

Identity    : Tag:Test-Teams-policy
AppIds      : {e1cd2318-298b-4916-bfd6-78cae9938835}
Description : Want App to be able to work with Teams for a User

PS C:\WINDOWS\system32> Grant-CsApplicationAccessPolicy -PolicyName Test-Teams-policy -Identity "4ee732c3-322e-4a6b-b729-2fd1eb5c6004"
PS C:\WINDOWS\system32>

Note: This example uses the new "Integrated OAuth2 Client Credentials" feature introduced in Chilkat v9.5.0.96.

For more information, see https://learn.microsoft.com/en-us/graph/api/onlinemeeting-update?view=graph-rest-1.0&tabs=http

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' Provide the information needed for Chilkat to automatically fetch the OAuth2.0 
' access token as needed.
' This is the new "Integrated OAuth2 Client Credentials" feature introduced in Chilkat v9.5.0.96.  
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonOAuthCC = CreateObject("Chilkat.JsonObject")

' --------------------------------------------------------------------------------------------------------
' You'll need to have registered an app in Azure beforehand.
' 
' Note: Creating an online meeting requires the following Application permission:  OnlineMeetings.ReadWrite.All
' 
' See How to Create an Azure App Registration for OAuth 2.0 Client Credentials
' --------------------------------------------------------------------------------------------------------

' Use the values from your App Registration in Azure.
success = jsonOAuthCC.UpdateString("client_id","e1cd2318-xxxx-4916-bfd6-xxxxxxxxxxxx")
success = jsonOAuthCC.UpdateString("client_secret","K.d8Q~RoJxxxxvCj_u_xxxxxxxxxxxxxxxxxxxxx")

' You'll always use this scope for client credentials, because the allowed actions
' are determined by the App Permissions defined when you registered the app in Azure.
success = jsonOAuthCC.UpdateString("scope","https://graph.microsoft.com/.default")

' The token endpoint includes your tenant ID.  Use your tenant ID (not the tenant ID shown here).
success = jsonOAuthCC.UpdateString("token_endpoint","https://login.microsoftonline.com/112d7ed6-71bf-4eba-a866-738364321bfc/oauth2/v2.0/token")

' Provide the OAuth2 information. Chilkat will use this information to automatically fetch the OAuth2 access token as needed,
http.AuthToken = jsonOAuthCC.Emit()

' -------------------------------------------------------------------------------------------
' The following JSON is sent in the request body.

' {
'   "startDateTime": "2023-12-14T14:33:30-07:00",
'   "endDateTime": "2023-12-14T15:03:30-07:00",
'   "subject": "Patch Meeting Subject"
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("startDateTime","2023-12-14T14:33:30-07:00")
success = json.UpdateString("endDateTime","2023-12-14T15:03:30-07:00")
success = json.UpdateString("subject","Patch Meeting Subject")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbRequestBody = CreateObject("Chilkat.StringBuilder")
success = json.EmitSb(sbRequestBody)

' To update an online meeting, send a PATCH request like this:
' 
' PATCH https://graph.microsoft.com/v1.0/users/{userId}/onlineMeetings/{meetingId}
' Content-Type: application/json 
' 
' {
'   "startDateTime": "2020-09-09T14:33:30.8546353-07:00",
'   "endDateTime": "2020-09-09T15:03:30.8566356-07:00",
'   "subject": "Patch Meeting Subject"
' }

userId = "4ee732c3-322e-4a6b-b729-2fd1eb5c6004"
meetingId = "MSo0ZWU3MzJjMy0zMjJlLTRhNmItYjcyOS0yZmQxZWI1YzYwMDQqMCoqMTk6bWVldGluZ19OemMwT0RGa1pESXRNV1ZoTkMwME9UQXpMV0psWXpJdFkyRXdNR0kzTVdNME5qTmpAdGhyZWFkLnYy"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbUrl = CreateObject("Chilkat.StringBuilder")
success = sbUrl.Append("https://graph.microsoft.com/v1.0/users/{userId}/onlineMeetings/{meetingId}")
numReplaced = sbUrl.Replace("{userId}",userId)
numReplaced = sbUrl.Replace("{meetingId}",meetingId)

' resp is a Chilkat.HttpResponse
Set resp = http.PTextSb("PATCH",sbUrl.GetAsString(),sbRequestBody,"utf-8","application/json",0,0)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' ----------------------------------------------------------------------------------------
' IMPORTANT: 

' If using Application access, you will get the following error unless you configure your application
' to manage online meetings on behalf of the user.  (Note that the user ID is in the URL shown above.)
' See  https://learn.microsoft.com/en-us/graph/cloud-communication-online-meeting-application-access-policy#allow-applications-to-access-online-meetings-on-behalf-of-a-user 
' 
' {
'   "error": {
'     "code": "General",
'     "message": "No application access policy found for this app.",
'     "innerError": {
'       "request-id": "1c9bd09a-a089-4afd-add4-eec2334135c8",
'       "date": "2023-11-17T16:26:53",
'       "client-request-id": "1c9bd09a-a089-4afd-add4-eec2334135c8"
'     }
'   }
' }
' ----------------------------------------------------------------------------------------

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonResp = CreateObject("Chilkat.JsonObject")
success = jsonResp.Load(resp.BodyStr)
jsonResp.EmitCompact = 0
outFile.WriteLine(jsonResp.Emit())

statusCode = resp.StatusCode
outFile.WriteLine("response status code = " & statusCode)

If (statusCode <> 200) Then
    outFile.WriteLine("Failed.")
    WScript.Quit
End If

' Here is a sample response:

' Use the following online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

' {
'   "@odata.context": "https://graph.microsoft.com/v1.0/$metadata#users('4ee732c3-322e-4a6b-b729-2fd1eb5c6004')/onlineMeetings/$entity",
'   "id": "MSo0ZWU3MzJjMy0zMjJlLTRhNmItYjcyOS0yZmQxZWI1YzYwMDQqMCoqMTk6bWVldGluZ19OemMwT0RGa1pESXRNV1ZoTkMwME9UQXpMV0psWXpJdFkyRXdNR0kzTVeNME5qTmpAdGhyZWFkLnYy",
'   "creationDateTime": "2023-11-17T18:28:15.9746525Z",
'   "startDateTime": "2023-12-14T21:33:30Z",
'   "endDateTime": "2023-12-14T22:03:30Z",
'   "joinUrl": "https://teams.microsoft.com/l/meetup-join/19%3ameeting_Nzd0ODFkZDItMWVhNC00OTAzLWJlYzItY2EwMGI3MWM0NjNj%40thread.v2/0?context=%7b%22Tid%22%3a%22112d7ed6-71bf-4eba-a866-738364321bfc%22%2c%22Oid%22%3a%224ee732c3-322e-4a6b-b729-2fd1eb5c6004%22%7d",
'   "meetingCode": "215394732897",
'   "isBroadcast": false,
'   "autoAdmittedUsers": "everyoneInCompany",
'   "outerMeetingAutoAdmittedUsers": null,
'   "capabilities": [
'   ],
'   "externalId": null,
'   "iCalUid": null,
'   "meetingType": null,
'   "meetingMigrationMode": null,
'   "joinWebUrl": "https://teams.microsoft.com/l/meetup-join/19%3ameeting_Nzd0ODFkZDItMWVhNC00OTAzLWJlYzItY2EwMGI3MWM0NjNj%40thread.v2/0?context=%7b%22Tid%22%3a%22112d7ed6-71bf-4eba-a866-738364321bfc%22%2c%22Oid%22%3a%224ee732c3-322e-4a6b-b729-2fd1eb5c6004%22%7d",
'   "subject": "Patch Meeting Subject",
'   "videoTeleconferenceId": null,
'   "isEntryExitAnnounced": true,
'   "allowedPresenters": "everyone",
'   "allowAttendeeToEnableMic": true,
'   "allowAttendeeToEnableCamera": true,
'   "allowMeetingChat": "enabled",
'   "shareMeetingChatHistoryDefault": "none",
'   "allowTeamworkReactions": true,
'   "anonymizeIdentityForRoles": [
'   ],
'   "recordAutomatically": false,
'   "allowParticipantsToChangeName": false,
'   "allowTranscription": true,
'   "allowRecording": true,
'   "broadcastSettings": null,
'   "meetingInfo": null,
'   "audioConferencing": null,
'   "watermarkProtection": null,
'   "chatRestrictions": null,
'   "participants": {
'     "organizer": {
'       "upn": "admin@chilkat365.com",
'       "role": "presenter",
'       "identity": {
'         "application": null,
'         "device": null,
'         "user": {
'           "id": "4ee732c3-322e-4a6b-b729-2fd1eb5c6004",
'           "displayName": null,
'           "tenantId": "112d7ed6-71bf-4eba-a866-738364321bfc",
'           "identityProvider": "AAD"
'         }
'       }
'     },
'     "attendees": [
'     ]
'   },
'   "chatInfo": {
'     "threadId": "19:meeting_Nzc0ODFkZDItMWVhNC00OTAzLWJlYzItY2EwMGI3MWM0NjNj@thread.v2",
'     "messageId": "0",
'     "replyChainMessageId": null
'   },
'   "joinInformation": {
'     "content": "data:text/html,%3cdiv+style ... %2fdiv%3e",
'     "contentType": "html"
'   },
'   "joinMeetingIdSettings": {
'     "isPasscodeRequired": false,
'     "joinMeetingId": "215394732897",
'     "passcode": null
'   },
'   "lobbyBypassSettings": {
'     "scope": "organization",
'     "isDialInBypassEnabled": false
'   }
' }

' Use the following online tool to generate parsing code from sample JSON: 
' Generate Parsing Code from JSON

outFile.WriteLine("Success.")

outFile.Close