(VBScript) Microsoft Teams - Create Team (minimal request)

The following is an example of a minimal request to create a Team. By omitting other properties, the client is implicitly taking defaults from the pre-defined template represented by template.

For more information, see https://docs.microsoft.com/en-us/graph/api/team-post?view=graph-rest-1.0&tabs=http#request

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' To create a Microsoft Team, we want to send an HTTP request like the following:

' POST https://graph.microsoft.com/v1.0/teams
' Content-Type: application/json
' 
' {
'   "template@odata.bind": "https://graph.microsoft.com/v1.0/teamsTemplates('standard')",
'   "displayName": "My Sample Team",
'   "description": "My Sample Team’s Description"
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("""template@odata.bind""","https://graph.microsoft.com/v1.0/teamsTemplates('standard')")
success = json.UpdateString("displayName","My Sample Team")
success = json.UpdateString("description","My Sample Team’s Description")

http.SetRequestHeader "Content-type","application/json"

' Adds the "Authorization: Bearer ACCESS_TOKEN" header.
http.AuthToken = "ACCESS_TOKEN"

' resp is a Chilkat.HttpResponse
Set resp = http.PostJson3("https://graph.microsoft.com/v1.0/teams","application/json",json)
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' A successful response is indicated by a 202 response status code and an empty response body.
outFile.WriteLine("Response Status Code: " & resp.StatusCode)
outFile.WriteLine("Response Body:")
outFile.WriteLine(resp.BodyStr)

If (resp.StatusCode >= 400) Then
    outFile.WriteLine("Response Header:")
    outFile.WriteLine(resp.Header)
    outFile.WriteLine("Failed.")
End If


outFile.Close