VBScript

Group: Refresh OAuth2 Access Token

See more Microsoft Group Examples

Refreshes an expired or non-expired OAuth2 access token for the Microsoft Group REST API. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set json = CreateObject("Chilkat.JsonObject")
success = json.LoadFile("qa_data/tokens/msGraphGroup.json")
If (success <> 1) Then
    WScript.Quit
End If

set req = CreateObject("Chilkat.HttpRequest")
req.AddParam "grant_type","refresh_token"
req.AddParam "redirect_uri","http://localhost:3017/"
req.AddParam "client_id","MICROSOFT-GRAPH-CLIENT-ID"
req.AddParam "client_secret","MICROSOFT-GRAPH-CLIENT-SECRET"
req.AddParam "refresh_token",json.StringOf("refresh_token")
req.AddParam "scope","openid profile offline_access user.readwrite group.readwrite.all files.readwrite"

set http = CreateObject("Chilkat.Http")

req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpReq("https://login.microsoftonline.com/common/oauth2/v2.0/token",req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Load the JSON response.
success = json.Load(resp.BodyStr)
json.EmitCompact = 0

' Show the JSON response.
outFile.WriteLine(json.Emit())

outFile.WriteLine("Response status code: " & resp.StatusCode)

' If the response status code is not 200, then it's an error.
If (resp.StatusCode <> 200) Then
    WScript.Quit
End If

' Save the refreshed access token JSON to a file for future requests.
set fac = CreateObject("Chilkat.FileAccess")
success = fac.WriteEntireTextFile("qa_data/tokens/msGraphGroup.json",json.Emit(),"utf-8",0)

outFile.WriteLine("Success.")

outFile.Close