(VBScript) Extract Files from Binary SOAP MTOM MIME

This example demonstrates how to extract files from a binary SOAP MTOM MIME document.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Mime")
set mime = CreateObject("Chilkat.Mime")

' In this example, we have a MIME file containing 8bit (non-encoded) binary data,
' and it is what I call "headless".  MIME is headless when it omits
' the top-level header.  The file we have here begins with the first
' boundary string.

' The structure the MIME to be loaded is:

' multipart/mixed (inferred because it is headless)
'     application/xop+xml
'     image/jpeg
'     image/gif
'     image/gif
' 

success = mime.LoadMimeFile("qa_data/mime/headless_binary_soap_mtom_mime.mim")
If (success <> 1) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

' The MIME file loaded in this example contains this:

' --uuid:e74486f4-52b0-44b6-b829-156810fae20d
' Content-Type: application/xop+xml; charset=UTF-8; type="application/soap+xml"
' Content-Transfer-Encoding: binary
' Content-ID: <root.message@cxf.apache.org>
' 
' <soap:Envelope xmlns:soap="http://www.w3.org/2003/05/soap-envelope"><soap:Body> ... </soap:Body></soap:Envelope>
' --uuid:e74486f4-52b0-44b6-b829-156810fae20d
' Content-Type: image/jpeg
' Content-Transfer-Encoding: binary
' Content-ID: <beee83b7-166c-494c-890a-def990e9887b-1496@cxf.apache.org>
' Content-Disposition: attachment;name="-2049913191"
' 
' BINARY DATA HERE...
' 
' --uuid:e74486f4-52b0-44b6-b829-156810fae20d
' Content-Type: image/gif
' Content-Transfer-Encoding: binary
' Content-ID: <beee83b7-166c-494c-890a-def990e9887b-1497@cxf.apache.org>
' Content-Disposition: attachment;name="-2049913188"
' 
' BINARY DATA HERE...
' 
' --uuid:e74486f4-52b0-44b6-b829-156810fae20d
' Content-Type: image/gif
' Content-Transfer-Encoding: binary
' Content-ID: <beee83b7-166c-494c-890a-def990e9887b-1498@cxf.apache.org>
' Content-Disposition: attachment;name="-2049913185"
' 
' BINARY DATA HERE...
' 
' --uuid:e74486f4-52b0-44b6-b829-156810fae20d--

' Get the number of MIME sub-parts.
numParts = mime.NumParts

' The 1st part at index 0 is the application/xop+xml.  We're just going to extract the JPG and GIF image files..
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbFilename = CreateObject("Chilkat.StringBuilder")

i = 1
Do While i < numParts
    ' mp is a Chilkat.Mime
    Set mp = mime.GetPart(i)

    ' By looking at the MIME above, the "name" attribute of the Content-Disposition header field seems
    ' to be the only possible name we can use for each image..
    success = sbFilename.Append("qa_output/")
    name = mp.GetHeaderFieldAttribute("Content-Disposition","name")
    success = sbFilename.Append(name)
    success = sbFilename.Append(".")
    success = sbFilename.Append(mp.ContentType)
    numReplaced = sbFilename.Replace("image/","")
    success = mp.SaveBody(sbFilename.GetAsString())
    outFile.WriteLine("output file: " & sbFilename.GetAsString())

    sbFilename.Clear 
    i = i + 1
Loop

outFile.WriteLine("Success.")

outFile.Close