(VBScript) Extract PKCS7 from MIME and Decrypt

Extracts the base64-encoded PKCS7 body of a MIME message to a file, and then decrypts using Chilkat Crypt2.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Mime")
set mime = CreateObject("Chilkat.Mime")

success = mime.LoadMimeFile("c:/aaworkarea/EmailInBytes.txt")
If (success <> 1) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

success = mime.SaveBody("c:/aaworkarea/smime.p7m")
If (success <> 1) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

success = crypt.AddPfxSourceFile("c:/aaworkarea/my.pfx","pfxPassword")
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' Indicate the public-key (PKCS7) encryption/decryption should be used:
crypt.CryptAlgorithm = "pki"

inPath = "c:/aaworkarea/smime.p7m"
outPath = "c:/aaworkarea/decrypted.dat"

success = crypt.CkDecryptFile(inPath,outPath)
If (success = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close