(VBScript) The MIME Content-Type Header Field

Explains the ContentType property and the Content-Type header field including the various attributes that may be included.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Every part in a MIME messsage should include a Content-Type header field.
' The Content-Type indicates the type of content contained in the MIME part.
' For example: text/plain, image/jpeg, application/pdf, application/json, multipart/mixed, etc.

' Multipart content types are those where the MIME part's body is composed of N inner MIME messages,
' separated by a boundary string.
' This is how MIME gets a nested, tree-like structure.  The most common multipart MIME types
' are (for email related MIME) multipart/mixed, multipart/alternative, and multipart/related,
' and for HTTP related MIME, it is multipart/form-data.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Mime")
set mime = CreateObject("Chilkat.Mime")

' The Content-Type header field can be set or modified in two ways.
' 1) By setting the ContentType, Micalg, Name, Charset, Boundary, or Protocol properties.
'    Setting the ContentType property sets the primary value (such as "text/plain") of the header field.
'    Each of the other properties listed above will replace or add a particular attribute value.

' 2) By setting the entire contents of the ContentType header with the SetHeaderField method.
'    This updates each of the Content-Type related properties.

' For example:
mime.ContentType = "text/plain"
mime.Charset = "utf-8"

' The Content-Type header field contains this:
'     Content-Type: text/plain; charset=utf-8
outFile.WriteLine(mime.GetEntireHead())
outFile.WriteLine("-")

success = mime.SetHeaderField("Content-Type","image/jpeg; name=""kitty.jpg""")
' The Content-Type header field now contains this:
'     Content-Type: image/jpeg; name="kitty.jpg"
outFile.WriteLine(mime.GetEntireHead())
outFile.WriteLine("-")

' Notice how the properties have been updated:
outFile.WriteLine("ContentType property: " & mime.ContentType)
outFile.WriteLine("Charset property: " & mime.Charset)
outFile.WriteLine("Name property: " & mime.Name)
outFile.WriteLine("-")

' To change a particular attribute value, set the property.
mime.Name = "doggy.jpg"
outFile.WriteLine(mime.GetEntireHead())
outFile.WriteLine("-")

' To remove an attribute value from the Content-Type header,
' set the property to an empty string.
mime.Name = ""
outFile.WriteLine(mime.GetEntireHead())
outFile.WriteLine("-")

outFile.Close