(VBScript) Setting the MIME Text Charset (such as utf-8, iso-8859-1, etc.)

Demonstrates how setting the Charset property controls the character encoding used for the text body in a MIME message.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Mime")
set mime = CreateObject("Chilkat.Mime")

' Set the MIME body using some 8bit non-us-ascii characters:
mime.SetBody "á, é, í, ó, ú"

' Set the Content-Type
mime.ContentType = "text/plain"

' Set the Content-Transfer-Encoding to "quoted-printable"
' so it's easy to see the bytes used to encode each character
' (i.e. it will be easy to see that utf-8 uses 2-bytes for 
' non-us-ascii characters such as "á", whereas a character
' encoding such as iso-8859-1 will use one byte per character.
mime.Encoding = "quoted-printable"

' Set the Charset to utf-8
mime.Charset = "utf-8"

' Examine the MIME:
outFile.WriteLine(mime.GetMime())

' The MIME should look like this:

' Content-Transfer-Encoding: quoted-printable
' Content-Type: text/plain; charset="utf-8"
' 
' =C3=A1, =C3=A9, =C3=AD, =C3=B3, =C3=BA

' Now change the Charset to "iso-8859-1"
mime.Charset = "iso-8859-1"

' Get the MIME again...
outFile.WriteLine(mime.GetMime())

' Now the MIME should look like this:

' Content-Transfer-Encoding: quoted-printable
' Content-Type: text/plain; charset="iso-8859-1"
' 
' =E1, =E9, =ED, =F3, =FA

outFile.Close