VBScript

Append Part to MIME

See more MIME Examples

Demonstrates the AppendPart method for adding sub-parts to MIME. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Create a text/plain part.
set ptMime = CreateObject("Chilkat.Mime")
success = ptMime.SetBodyFromPlainText("This is the plain text body")
outFile.WriteLine(ptMime.GetMime())
outFile.WriteLine("****")

' The ptMime contains:
' ---------------------------------------
' 	Content-Type: text/plain
' 	Content-Transfer-Encoding: 7bit
' 
' 	This is the plain text body
' ---------------------------------------

' Start with an empty MIME object...
set topLevelMime = CreateObject("Chilkat.Mime")

' Initialize it to a multipart Content-Type.  We'll use multipart/mixed.
success = topLevelMime.NewMultipartMixed()

' Append the ptMime as a child.
success = topLevelMime.AppendPart(ptMime)
outFile.WriteLine(topLevelMime.GetMime())
outFile.WriteLine("****")

' The topLevelMime contains:
' --------------------------
' 	Content-Type: multipart/mixed; boundary="------------010907090104040508040404"
' 
' 	--------------010907090104040508040404
' 	Content-Type: text/plain
' 	Content-Transfer-Encoding: 7bit
' 
' 	This is the plain text body
' 	--------------010907090104040508040404--
' 

' IMPORTANT: A copy of the MIME passed in AppendPart is appended.
' Therefore, in this case, changing ptMime does not change the text/plain sub-part in topLevelMime.
' For example:
ptMime.SetBody "this is the new plain text body."
' topLevelMime is unchanged.
outFile.WriteLine(topLevelMime.GetMime())
outFile.WriteLine("****")

' To change the content in topLevelMime, we must get the text/plain part.
' For example:

set ptMime2 = CreateObject("Chilkat.Mime")
success = topLevelMime.PartAt(0,ptMime2)

ptMime2.SetBody "this is the new plain text body."
' Now topLevelMime is changed.
outFile.WriteLine(topLevelMime.GetMime())

outFile.Close