(VBScript) Convert HTML Web Page to Email and Send

Converts an HTML page at a URL into an email with embedded images and sends it.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.MailMan")
set mailman = CreateObject("Chilkat.MailMan")

' The MHT component can be used to convert an HTML page
' from a URL, file, or in-memory HTML into an email
' with embedded images and style sheets.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Mht")
set mht = CreateObject("Chilkat.Mht")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = CreateObject("Chilkat.Email")

' There are two ways of embedding images in emails: with CIDs
' and without.  When using CIDs, the IMG SRC attributes use
' urls that begin with "cid:" and the corresponding image
' embedded within the email includes a Content-ID header field.
' When not using CIDs, the IMG SRC attribute can have a URL,
' path, etc. and the corresponding image embedded within
' the email has a matching Content-Location header field.

' When testing with GMail, if CIDs are used the email will
' be displayed with images blocked (by default) unless
' the user allows them to be displayed.  Without CIDs,
' the images are automatically displayed.

' When testing with Eudora, Mozilla Thunderbird, and Outlook Express, 
' embedded images display correctly with our without CIDs.

' When testing with Yahoo! Mail, embedded images display OK.
' However, the Yahoo! Mail user has the option of blocking
' images.  If this is turned on, the CID images will still 
' display correctly even though images are blocked.  Why?
' It's because when viewing the email there is no external
' HTTP request to fetch an image.  Therefore, a spammer 
' cannot get an indication that you've read the email. 
' However, if CIDs are not used, the images are blocked by 
' any Yahoo! Mail user that has image blocking turned on --
' even though the images are embedded.

' I haven't tested Hotmail yet...
' Regardless, there is no perfect solution.  If CIDs are used,
' GMail users may block your embedded images, if CIDs are not
' used, Yahoo! Mail users may block your embedded images.

' I recommend setting using CIDs.  This is what Mozilla Thunderbird
' does by default, and it's the more clear an unambiguous way
' to indicate that images are indeed embedded.
mht.UseCids = 1

emlStr = mht.GetEML("http://www.bonairefishing.com/")
If (mht.LastMethodSuccess <> 1) Then
    outFile.WriteLine(mht.LastErrorText)
    WScript.Quit
End If

success = email.SetFromMimeText(emlStr)
If (success <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

email.Subject = "Test HTML email"

' This example is tested in:
' Outlook 2000, Eudora 7, Mozilla Thunderbird 1.5.0.9, Outlook Express 6, GMail, Yahoo Mail
success = email.AddTo("Chilkat Support","support@chilkatsoft.com")

' Note: Chilkat does not regularly check our GMail and Yahoo
' email accounts.  Please send support email to support@chilkatsoft.com
success = email.AddTo("Chilkat on Yahoo","chilkat_software@yahoo.com")
success = email.AddTo("Chilkat on GMail","chilkat.support@gmail.com")

email.From = "chilkat@live.com"

' Send email using smtp.live.com
mailman.SmtpHost = "smtp.live.com"
mailman.SmtpUsername = "chilkat@live.com"
mailman.SmtpPassword = "myPassword"
mailman.SmtpPort = 587
mailman.StartTLS = 1

success = mailman.SendEmail(email)
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    outFile.WriteLine(mailman.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("HTML Email Sent!")

outFile.Close