VBScript

Windows Credentials Manager / Apple Keychain - Create or Update a Binary Secret

See more Secrets Examples

On Windows, creates or updates a binary secret in the Windows Credentials Manager.

On MacOS or iOS, creates or updates a binary secret in the Apple Keychain.

Note: This example requires Chilkat v10.1.0 or later.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set secrets = CreateObject("Chilkat.Secrets")

' On Windows, this is the Windows Credentials Manager
' On MacOS/iOS, it is the Apple Keychain
secrets.Location = "local_manager"

' Specify the name of the secret.
' service and username are required.
' appName and domain are optional.
' Note: The values are arbitrary and can be anything you want.
set json = CreateObject("Chilkat.JsonObject")
success = json.UpdateString("appName","Test2")
success = json.UpdateString("service","Custom")
success = json.UpdateString("domain","Ocean")
success = json.UpdateString("username","Starfish20")

' The purpose of this example is to show how arbitrary binary data
' can be stored as a secret.

' We'll use a small JPG image that is approximately 2KB in size.
' You can test using this same JPG at this URL:
url = "https://chilkatdownload.com/sample_data/starfish20.jpg"
set http = CreateObject("Chilkat.Http")
set bd = CreateObject("Chilkat.BinData")
success = http.DownloadBd(url,bd)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Create or update the binary secret.
success = secrets.UpdateSecretBd(json,bd)
If (success = 0) Then
    outFile.WriteLine(secrets.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Success.")

outFile.Close