(VBScript) Verify JWT Using HS256, HS384, or HS512

Demonstrates how to verify a JWT that was signed using HS256, HS384, or HS512. (HS256 is JWT's acronym for HMAC-SHA256.)

This example verifies the signature. It also does the following:

• Checks to see if the time constraints ("nbf" and "exp") are valid.
• Recovers the original JOSE header.
• Recovers the original claims JSON.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Demonstrates how to verify an HMAC JWT using a shared secret (password).

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Jwt")
set jwt = CreateObject("Chilkat.Jwt")

token = "eyJhbGciOiJIUzI1NiIsInR5cCI6IkpXVCJ9.eyJpc3MiOiJodHRwOi8vZXhhbXBsZS5vcmciLCJzdWIiOiJKb2huIiwiYXVkIjoiaHR0cDovL2V4YW1wbGUuY29tIiwiaWF0IjoxNDYzNDMxODEyLCJuYmYiOjE0NjM0MzE4MTIsImV4cCI6MTQ2MzQzNTQxMn0.SHnMJ11qJH5pbp22YchT_9fL2HIx0koHiUHLG67_foU"

' First verify the signature.
' The password used to create this JWT was "secret".
sigVerified = jwt.VerifyJwt(token,"secret")
outFile.WriteLine("with correct password: " & sigVerified)

' Now try with a different password:
sigVerified = jwt.VerifyJwt(token,"secret2")
outFile.WriteLine("with incorrect password " & sigVerified)

' Let's see if the time constraints, if any, are valid.
' The above JWT was created on the afternoon of 16-May-2016, with an expiration of 1 hour.
' If the current system time is before the "nbf" time, or after the "exp" time,
' then IsTimeValid will return false/0.
' Also, we'll allow a leeway of 60 seconds to account for any clock skew.
' Note: If the token has no "nbf" or "exp" claim fields, then IsTimeValid is always true.
leeway = 60
bTimeValid = jwt.IsTimeValid(token,leeway)
outFile.WriteLine("time constraints valid: " & bTimeValid)

' Now let's recover the original claims JSON (the payload).
payload = jwt.GetPayload(token)
' The payload will likely be in compact form:
outFile.WriteLine(payload)

' We can format for human viewing by loading it into Chilkat's JSON object
' and emit.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(payload)
json.EmitCompact = 0
outFile.WriteLine(json.Emit())

' We can recover the original JOSE header in the same way:
joseHeader = jwt.GetHeader(token)
' The payload will likely be in compact form:
outFile.WriteLine(joseHeader)

' We can format for human viewing by loading it into Chilkat's JSON object
' and emit.
success = json.Load(joseHeader)
json.EmitCompact = 0
outFile.WriteLine(json.Emit())

outFile.Close