VBScript

Verify JWT Using an ECC Public Key (ES256, ES384, ES512)

See more JSON Web Token (JWT) Examples

Demonstrates how to verify a JWT that was signed using an ECC private key.

This example verifies the ECC signature. It also does the following:

• Checks to see if the time constraints ("nbf" and "exp") are valid.
• Recovers the original JOSE header.
• Recovers the original claims JSON.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' Demonstrates how to verify an JWT using an ECC public key.

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set pubKey = CreateObject("Chilkat.PublicKey")
success = pubKey.LoadFromFile("qa_data/pem/ecc_public.pem")

set jwt = CreateObject("Chilkat.Jwt")

token = "eyJhbGciOiJFUzI1NiIsInR5cCI6IkpXVCJ9.eyJpc3MiOiJodHRwOi8vZXhhbXBsZS5vcmciLCJzdWIiOiJKb2huIiwiYXVkIjoiaHR0cDovL2V4YW1wbGUuY29tIiwiaWF0IjoxNDg1NzA4NzkyLCJuYmYiOjE0ODU3MDg3OTIsImV4cCI6MTQ4NTcxMjM5Mn0.wqsuyJpxJ073ox-lOiLFqG1lQocXe4hGf2XGZJRrO3qn0UusxI_bu3Gzky8gBsH4sA4u9TWZn5M-1wYMMIJk6Q"

' First verify the signature.
sigVerified = jwt.VerifyJwtPk(token,pubKey)
outFile.WriteLine("verified: " & sigVerified)

' Let's see if the time constraints, if any, are valid.
' The above JWT was created on the afternoon of 16-May-2016, with an expiration of 1 hour.
' If the current system time is before the "nbf" time, or after the "exp" time,
' then IsTimeValid will return false/0.
' Also, we'll allow a leeway of 60 seconds to account for any clock skew.
' Note: If the token has no "nbf" or "exp" claim fields, then IsTimeValid is always true.
leeway = 60
bTimeValid = jwt.IsTimeValid(token,leeway)
outFile.WriteLine("time constraints valid: " & bTimeValid)

' Now let's recover the original claims JSON (the payload).
payload = jwt.GetPayload(token)
' The payload will likely be in compact form:
outFile.WriteLine(payload)

' We can format for human viewing by loading it into Chilkat's JSON object
' and emit.
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(payload)
json.EmitCompact = 0
outFile.WriteLine(json.Emit())

' We can recover the original JOSE header in the same way:
joseHeader = jwt.GetHeader(token)
' The payload will likely be in compact form:
outFile.WriteLine(joseHeader)

' We can format for human viewing by loading it into Chilkat's JSON object
' and emit.
success = json.Load(joseHeader)
json.EmitCompact = 0
outFile.WriteLine(json.Emit())

outFile.Close