(VBScript) Create JWT Using HS256, HS384, or HS512

Demonstrates how to create a JWT using HS256, HS384, or HS512. (HS256 is JWT's acronym for HMAC-SHA256.) When HMAC is used, the secret is a shared secret (i.e. password) that both client and server know beforehand.

This example also demonstrates how to include time constraints:

• nbf: Not Before Time
• exp: Expiration Time
• iat: Issue At Time

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Demonstrates how to create an HMAC JWT using a shared secret (password).

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Jwt")
set jwt = CreateObject("Chilkat.Jwt")

' Build the JOSE header
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jose = CreateObject("Chilkat.JsonObject")
' Use HS256.  Pass the string "HS384" or "HS512" to use a different algorithm.
success = jose.AppendString("alg","HS256")
success = jose.AppendString("typ","JWT")

' Now build the JWT claims (also known as the payload)
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set claims = CreateObject("Chilkat.JsonObject")
success = claims.AppendString("iss","http://example.org")
success = claims.AppendString("sub","John")
success = claims.AppendString("aud","http://example.com")

' Set the timestamp of when the JWT was created to now.
curDateTime = jwt.GenNumericDate(0)
success = claims.AddIntAt(-1,"iat",curDateTime)

' Set the "not process before" timestamp to now.
success = claims.AddIntAt(-1,"nbf",curDateTime)

' Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = claims.AddIntAt(-1,"exp",curDateTime + 3600)

' Produce the smallest possible JWT:
jwt.AutoCompact = 1

strJwt = jwt.CreateJwt(jose.Emit(),claims.Emit(),"secret")

outFile.WriteLine(strJwt)

outFile.Close