VBScript

Create JWT Using Ed25519 Private Key (EdDSA)

See more JSON Web Token (JWT) Examples

Demonstrates how to create a JWT using an Ed25519 private key. If the private key is Ed25519, which is an EdDSA algorithm, the JOSE header's "alg" member should be set to "EdDSA".

Note: This example requires Chilkat v9.5.0.95 or greater.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Demonstrates how to create a JWT using an Ed25519 private key.

set privKey = CreateObject("Chilkat.PrivateKey")

' Load an Ed25519 (EdDSA) private key from a PEM file.
success = privKey.LoadPemFile("qa_data/eddsa/ed25519.pem")
If (success <> 1) Then
    outFile.WriteLine(privKey.LastErrorText)
    WScript.Quit
End If

set jwt = CreateObject("Chilkat.Jwt")

' Build the JOSE header
set jose = CreateObject("Chilkat.JsonObject")

' -----------------------------------------------------------------
' Note: This example requires Chilkat v9.5.0.95 or greater.
' -----------------------------------------------------------------
success = jose.AppendString("alg","EdDSA")
success = jose.AppendString("typ","JWT")

' Now build the JWT claims (also known as the payload)
set claims = CreateObject("Chilkat.JsonObject")
success = claims.AppendString("iss","http://example.org")
success = claims.AppendString("sub","John")
success = claims.AppendString("aud","http://example.com")

' (optional) Set the timestamp of when the JWT was created to now.
curDateTime = jwt.GenNumericDate(0)
success = claims.AddIntAt(-1,"iat",curDateTime)

' (optional)  Set the "not process before" timestamp to now.
success = claims.AddIntAt(-1,"nbf",curDateTime)

' (optional)  Set the timestamp defining an expiration time (end time) for the token
' to be now + 1 hour (3600 seconds)
success = claims.AddIntAt(-1,"exp",curDateTime + 3600)

' Produce the smallest possible JWT:
jwt.AutoCompact = 1

' Create the JWT token.
token = jwt.CreateJwtPk(jose.Emit(),claims.Emit(),privKey)

outFile.WriteLine(token)

' Example output:
' eyJhbGciOiJFZERTQSIsInR5cCI6IkpXVCJ9.eyJpc3MiOiJodHRwOi8vZXhhbXBsZS5vcmciLCJzdWIiOiJKb2huIiwiYXVkIjoiaHR0cDovL2V4YW1wbGUuY29tIiwiaWF0IjoxNjg3OTcwNjgyLCJuYmYiOjE2ODc5NzA2ODIsImV4cCI6MTY4Nzk3NDI4Mn0.eyfrDJfuWJSJVJPfAUYb_p_c-LF_YULHGRaZx82MLLjMLCCFEEGckp8icuayf5bLW9ah20LzYYt0JgOBIB0RDg

outFile.Close