(VBScript) Validate a JWS Using ECDSA P-521 SHA-512

Validates a JSON Web Signature (JWS) that uses ECDSA P-521 SHA-512

Note: This example requires Chilkat v9.5.0.66 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.

' This example takes a JSON signature in compact serialization format,
' and uses an ECDSA public key to validate and recover the protected header and payload.

' We only need a public key for signature validation.  This is the ECDSA public key
' that is used:

'      {"kty":"EC", 
'       "crv":"P-521", 
'       "x":"AekpBQ8ST8a8VcfVOTNl353vSrDCLLJXmPk06wTjxrrjcBpXp5EOnYG_NjFZ6OvLFV1jSfS9tsz4qUxcWceqwQGk", 
'       "y":"ADSmRA43Z1DSNx_RvcLI87cdL07l6jQyyBXMoxVg_l2Th-x3S1WDhjDly79ajL4Kkd0AZMaZmh9ubmf63e3kyMj2" 
'      } 

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbPubKey = CreateObject("Chilkat.StringBuilder")
success = sbPubKey.Append("{""kty"":""EC"",")
success = sbPubKey.Append("""crv"":""P-521"",")
success = sbPubKey.Append("""x"":""AekpBQ8ST8a8VcfVOTNl353vSrDCLLJXmPk06wTjxrrjcBpXp5EOnYG_NjFZ6OvLFV1jSfS9tsz4qUxcWceqwQGk"",")
success = sbPubKey.Append("""y"":""ADSmRA43Z1DSNx_RvcLI87cdL07l6jQyyBXMoxVg_l2Th-x3S1WDhjDly79ajL4Kkd0AZMaZmh9ubmf63e3kyMj2""")
success = sbPubKey.Append("}")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.PublicKey")
set pubKey = CreateObject("Chilkat.PublicKey")
success = pubKey.LoadFromString(sbPubKey.GetAsString())
If (success <> 1) Then
    outFile.WriteLine(pubKey.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Jws")
set jws = CreateObject("Chilkat.Jws")

' Set the ECC public key:
signatureIndex = 0
success = jws.SetPublicKey(signatureIndex,pubKey)

' Load the JWS.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbJws = CreateObject("Chilkat.StringBuilder")
success = sbJws.Append("eyJhbGciOiJFUzUxMiJ9")
success = sbJws.Append(".")
success = sbJws.Append("UGF5bG9hZA")
success = sbJws.Append(".")
success = sbJws.Append("AdwMgeerwtHoh-l192l60hp9wAHZFVJbLfD_UxMi70cwnZOYaRI1bKPWROc-mZZq")
success = sbJws.Append("wqT2SI-KGDKB34XO0aw_7XdtAG8GaSwFKdCAPZgoXD2YBJZCPEX3xKpRwcdOO8Kp")
success = sbJws.Append("EHwJjyqOgzDO7iKvU8vcnwNrmxYbSW9ERBXukOXolLzeO_Jn")

success = jws.LoadJwsSb(sbJws)
If (success <> 1) Then
    outFile.WriteLine(jws.LastErrorText)
    WScript.Quit
End If

' Validate the 1st (and only) signature at index 0..
v = jws.Validate(signatureIndex)
If (v < 0) Then
    ' Perhaps Chilkat was not unlocked or the trial expired..
    outFile.WriteLine("Method call failed for some other reason.")
    outFile.WriteLine(jws.LastErrorText)
    WScript.Quit
End If

If (v = 0) Then
    outFile.WriteLine("Invalid signature.  The ECC key was incorrect, the JWS was invalid, or both.")
    WScript.Quit
End If

' If we get here, the signature was validated..
outFile.WriteLine("Signature validated.")
outFile.WriteLine("--")

' Recover the original content:
outFile.WriteLine("Recovered content:")
outFile.WriteLine(jws.GetPayload("utf-8"))
outFile.WriteLine("--")

' Examine the protected header:
' joseHeader is a Chilkat.JsonObject
Set joseHeader = jws.GetProtectedHeader(signatureIndex)
If (jws.LastMethodSuccess <> 1) Then
    outFile.WriteLine("No protected header found at the given index.")
    WScript.Quit
End If

joseHeader.EmitCompact = 0

outFile.WriteLine("Protected (JOSE) header:")
outFile.WriteLine(joseHeader.Emit())

' Output:
' (the string "Payload" was the content that was signed.)

' 	Signature validated.
' 	--
' 	Recovered content:
' 	Payload
' 	--
' 	Protected (JOSE) header:
' 	{
' 	  "alg": "ES512"
' 	}

outFile.Close