(VBScript) Create JWS Using Private Key on a Smart Card

See more JSON Web Signatures (JWS) Examples

Creates and validates a JSON Web Signature (JWS) using the private key associated with a certificate on a smart card.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Load the certificate from a smart card.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
success = cert.LoadFromSmartcard("")
If (success = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Note: Chilkat provides many different ways to load a certificate from a smartcard or USB token,
' such as selecting a certificate if the card contains multiple certificates with private keys,
' or working with lower-level PKCS11 or ScMinidriver API's (both of which Chilkat provides).

' If the associated private key was present on the smartcard, then you can simply
' get it from the Chilkat cert object:
' privKey is a Chilkat.PrivateKey
Set privKey = cert.ExportPrivateKey()
If (cert.LastMethodSuccess = 0) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' You can check the key type to make sure it's RSA.
' This will output "rsa" if the key is RSA.
outFile.WriteLine("Key type = " & privKey.KeyType)

' Create the JWS Protected Header
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jwsProtHdr = CreateObject("Chilkat.JsonObject")
success = jwsProtHdr.AppendString("alg","RS256")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Jws")
set jws = CreateObject("Chilkat.Jws")

' Set the protected header:
signatureIndex = 0
success = jws.SetProtectedHeader(signatureIndex,jwsProtHdr)

' Set the RSA key:
success = jws.SetPrivateKey(signatureIndex,privKey)

' Set the payload.
bIncludeBom = 0
payloadStr = "In our village, folks say God crumbles up the old moon into stars."
success = jws.SetPayload(payloadStr,"utf-8",bIncludeBom)

' Create the JWS
' By default, the compact serialization is used.
jwsCompact = jws.CreateJws()
If (jws.LastMethodSuccess <> 1) Then
    outFile.WriteLine(jws.LastErrorText)

    WScript.Quit
End If

outFile.WriteLine("JWS: " & jwsCompact)

' sample output:
' JWS: eyJhbGciOiJQUzI1NiJ9.SW4gb3VyIHZpbGxhZ2UsIGZvbGtzIHNheSBHb2QgY3J1bWJsZXMgdXAgdGhlIG9sZCBtb29uIGludG8gc3RhcnMu.TRWhwRo5dMv9-8OzrInfJTwmUGYgjLfHk8lqF072ND-FmLWEBnUTOpY8oJXp8FdWw2SalbdOeNlrtlJjwk4XK8Ql2iJ_2qMCtxsvLPhKBOqFoAF4aBvTOEDVJDxf0DaBSiydEEtfTVV2iwBcjWabu5J2XieR5y7QZQtuHsn7T3qKBvCcCejN3Y2oqAT3qMHvu1fTms1r_91wBn_K7Wjd9UkZ1n02qQcUHJznR_OF2BgN7_KWIDAF9ZS9keoju2NPpPelO4yxa2XUPnehY3G7dHKoCxUEQR4d2Xc5voqDASTVCDqQS4PVOZdvT3Ein6-SanAlCwbWBbkvT8g6-5PImQ

' Now load the JWS, validate, and recover the original text.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Jws")
set jws2 = CreateObject("Chilkat.Jws")

' Load the JWS.
success = jws2.LoadJws(jwsCompact)

' rsaPubKey is a Chilkat.PublicKey
Set rsaPubKey = privKey.GetPublicKey()

' Set the RSA public key used for validation.
signatureIndex = 0
success = jws2.SetPublicKey(signatureIndex,rsaPubKey)

' Validate the 1st (and only) signature at index 0..
v = jws2.Validate(signatureIndex)
If (v < 0) Then
    ' Perhaps Chilkat was not unlocked or the trial expired..
    outFile.WriteLine("Method call failed for some other reason.")
    outFile.WriteLine(jws2.LastErrorText)
    WScript.Quit
End If

If (v = 0) Then
    outFile.WriteLine("Invalid signature.  The RSA key was incorrect, the JWS was invalid, or both.")
    WScript.Quit
End If

' If we get here, the signature was validated..
outFile.WriteLine("Signature validated.")

' Recover the original content:
outFile.WriteLine(jws2.GetPayload("utf-8"))

' Examine the protected header:
' joseHeader is a Chilkat.JsonObject
Set joseHeader = jws2.GetProtectedHeader(signatureIndex)
If (jws2.LastMethodSuccess <> 1) Then
    outFile.WriteLine("No protected header found at the given index.")
    WScript.Quit
End If

joseHeader.EmitCompact = 0

outFile.WriteLine("Protected (JOSE) header:")
outFile.WriteLine(joseHeader.Emit())

' Output:

' 	Signature validated.
' 	In our village, folks say God crumbles up the old moon into stars.
' 	Protected (JOSE) header:
' 	{ 
' 	  "alg": "RS256"
' 	}

outFile.Close