(VBScript) JWS Using HMAC SHA-256

Creates a JSON Web Signatures (JWS) using HMAC SHA-256.

Note: This example requires Chilkat v9.5.0.66 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.

' First create the JWS Protected Header
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jwsProtHdr = CreateObject("Chilkat.JsonObject")
success = jwsProtHdr.AppendString("typ","JWT")
success = jwsProtHdr.AppendString("alg","HS256")
outFile.WriteLine("JWS Protected Header: " & jwsProtHdr.Emit())

' Output:
' JWS Protected Header: {"typ":"JWT","alg":"HS256"}

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Jws")
set jws = CreateObject("Chilkat.Jws")

' Set the HMAC key:
hmacKey = "AyM1SysPpbyDfgZld3umj1qzKObwVMkoqQ-EstJQLr_T-1qS0gZH75aKtMN3Yj0iPS4hcgUuTwjAzZr1Z9CAow"
signatureIndex = 0
success = jws.SetMacKey(signatureIndex,hmacKey,"base64url")

' Set the protected header:
success = jws.SetProtectedHeader(signatureIndex,jwsProtHdr)

' Set the payload.
bIncludeBom = 0
payloadStr = "In our village, folks say God crumbles up the old moon into stars."
success = jws.SetPayload(payloadStr,"utf-8",bIncludeBom)

' Create the JWS
' By default, the compact serialization is used.
jwsCompact = jws.CreateJws()
If (jws.LastMethodSuccess <> 1) Then
    outFile.WriteLine(jws.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("JWS: " & jwsCompact)

' sample output:
' JWS: eyJ0eXAiOiJKV1QiLCJhbGciOiJIUzI1NiJ9.SW4gb3VyIHZpbGxhZ2UsIGZvbGtzIHNheSBHb2QgY3J1bWJsZXMgdXAgdGhlIG9sZCBtb29uIGludG8gc3RhcnMu.bsYsi8HJ0N6OqGI1hKQ9QQRNPxxA5qMpcHLtOvXatk8

' Now load the JWS, validate, and recover the original text.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Jws")
set jws2 = CreateObject("Chilkat.Jws")

' Load the JWS.
success = jws2.LoadJws(jwsCompact)

' Set the MAC key used for validation.
signatureIndex = 0
success = jws2.SetMacKey(signatureIndex,hmacKey,"base64url")

' Validate the 1st (and only) signature at index 0..
v = jws2.Validate(signatureIndex)
If (v < 0) Then
    ' Perhaps Chilkat was not unlocked or the trial expired..
    outFile.WriteLine("Method call failed for some other reason.")
    outFile.WriteLine(jws2.LastErrorText)
    WScript.Quit
End If

If (v = 0) Then
    outFile.WriteLine("Invalid signature.  The MAC key was incorrect, the JWS was invalid, or both.")
    WScript.Quit
End If

' If we get here, the signature was validated..
outFile.WriteLine("Signature validated.")

' Recover the original content:
outFile.WriteLine(jws2.GetPayload("utf-8"))

' Examine the protected header:
' joseHeader is a Chilkat.JsonObject
Set joseHeader = jws2.GetProtectedHeader(signatureIndex)
If (jws2.LastMethodSuccess <> 1) Then
    outFile.WriteLine("No protected header found at the given index.")
    WScript.Quit
End If

joseHeader.EmitCompact = 0

outFile.WriteLine("Protected (JOSE) header:")
outFile.WriteLine(joseHeader.Emit())

' Output:

' 	Signature validated.
' 	In our village, folks say God crumbles up the old moon into stars.
' 	Protected (JOSE) header:
' 	{ 
' 	  "typ": "JWT",
' 	  "alg": "HS256"
' 	} 

outFile.Close