(VBScript) Create JWK Set Containing Certificates

Demonstrates how to create a JWK Set containing N certificates.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example creates the following JWK Set from two certificates:

' {
'   "keys": [
'     {
'       "kty": "RSA",
'       "use": "sig",
'       "kid": "BB8CeFVqyaGrGNuehJIiL4dfjzw",
'       "x5t": "BB8CeFVqyaGrGNuehJIiL4dfjzw",
'       "n": "nYf1jpn7cFdQ...9Iw",
'       "e": "AQAB",
'       "x5c": [
'         "MIIDBTCCAe2...Z+NTZo"
'       ]
'     },
'     {
'       "kty": "RSA",
'       "use": "sig",
'       "kid": "M6pX7RHoraLsprfJeRCjSxuURhc",
'       "x5t": "M6pX7RHoraLsprfJeRCjSxuURhc",
'       "n": "xHScZMPo8F...EO4QQ",
'       "e": "AQAB",
'       "x5c": [
'         "MIIC8TCCAdmgA...Vt5432GA=="
'       ]
'     }
'   ]
' }

' First get two certificates from files.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert1 = CreateObject("Chilkat.Cert")
success = cert1.LoadFromFile("qa_data/certs/brasil_cert.pem")
If (success <> 1) Then
    outFile.WriteLine(cert1.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert2 = CreateObject("Chilkat.Cert")
success = cert2.LoadFromFile("qa_data/certs/testCert.cer")
If (success <> 1) Then
    outFile.WriteLine(cert2.LastErrorText)
    WScript.Quit
End If

' We'll need this crypt object re-encode the SHA1 thumbprint from hex to base64.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")

' Let's begin with the 1st cert:
json.I = 0
success = json.UpdateString("keys[i].kty","RSA")
success = json.UpdateString("keys[i].use","sig")

hexThumbprint = cert1.Sha1Thumbprint
base64Thumbprint = crypt.ReEncode(hexThumbprint,"hex","base64")
success = json.UpdateString("keys[i].kid",base64Thumbprint)
success = json.UpdateString("keys[i].x5t",base64Thumbprint)

' (We're assuming these are RSA certificates)
' To get the modulus (n) and exponent (e), we need to get the cert's public key and then get its JWK.
' pubKey is a Chilkat.PublicKey
Set pubKey = cert1.ExportPublicKey()
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set pubKeyJwk = CreateObject("Chilkat.JsonObject")
success = pubKeyJwk.Load(pubKey.GetJwk())

success = json.UpdateString("keys[i].n",pubKeyJwk.StringOf("n"))
success = json.UpdateString("keys[i].e",pubKeyJwk.StringOf("e"))

' Now add the entire X.509 certificate 
success = json.UpdateString("keys[i].x5c[0]",cert1.GetEncoded())

' Now do the same for cert2..
json.I = 1

success = json.UpdateString("keys[i].kty","RSA")
success = json.UpdateString("keys[i].use","sig")

hexThumbprint = cert2.Sha1Thumbprint
base64Thumbprint = crypt.ReEncode(hexThumbprint,"hex","base64")
success = json.UpdateString("keys[i].kid",base64Thumbprint)
success = json.UpdateString("keys[i].x5t",base64Thumbprint)

' pubKey is a Chilkat.PublicKey
Set pubKey = cert2.ExportPublicKey()
success = pubKeyJwk.Load(pubKey.GetJwk())

success = json.UpdateString("keys[i].n",pubKeyJwk.StringOf("n"))
success = json.UpdateString("keys[i].e",pubKeyJwk.StringOf("e"))

' Now add the entire X.509 certificate 
success = json.UpdateString("keys[i].x5c[0]",cert2.GetEncoded())

' Emit the JSON..
json.EmitCompact = 0
outFile.WriteLine(json.Emit())

outFile.Close