VBScript

JWE using "dir" Direct use of Shared Symmetric Key

See more JSON Web Encryption (JWE) Examples

Demonstrates how to create a JWE using the "dir" alg -- which is to directly use a shared symmetric key.

Note: This example requires Chilkat v9.5.0.66 or greater.

VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This example requires Chilkat v9.5.0.66 or greater.

plaintext = "Live long and prosper."

set jwe = CreateObject("Chilkat.Jwe")

' First build the JWE Protected Header..
set jweProtHdr = CreateObject("Chilkat.JsonObject")
success = jweProtHdr.AppendString("alg","dir")
success = jweProtHdr.AppendString("enc","A128GCM")

' Don't forget to actually provide the protected header to the JWE object:
success = jwe.SetProtectedHeader(jweProtHdr)

' The JWE is to use 128-bit AES GCM encryption as specified by the "enc" parameter.
' Given that the "alg" = "dir", we are to directly specify the AES GCM key.
' (It is assumed that the decrypting side also has knowledge of the direct key to be used..)

' Our key will be these 16 hex bytes: 000102030405060708090A0B0C0D0E0F

' The SetWrappingKey method is also used for "dir" direct keys.
' However, if there are multiple recipients, they must all share the same CEK (Content Encryption Key),
' which is specified by calling SetWrappingKey with an index of 0.

recipientIndex = 0
success = jwe.SetWrappingKey(recipientIndex,"000102030405060708090A0B0C0D0E0F","hex")

' Encrypt and return the JWE:
strJwe = jwe.Encrypt(plaintext,"utf-8")
If (jwe.LastMethodSuccess <> 1) Then
    outFile.WriteLine(jwe.LastErrorText)
    WScript.Quit
End If

' Show the JWE we just created:
outFile.WriteLine(strJwe)

' Decrypt the JWE.
set jwe2 = CreateObject("Chilkat.Jwe")
success = jwe2.LoadJwe(strJwe)
If (success <> 1) Then
    outFile.WriteLine(jwe2.LastErrorText)
    WScript.Quit
End If

success = jwe2.SetWrappingKey(0,"000102030405060708090A0B0C0D0E0F","hex")

' Decrypt.
originalPlaintext = jwe2.Decrypt(0,"utf-8")
If (jwe2.LastMethodSuccess <> 1) Then
    outFile.WriteLine(jwe2.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("original text: ")
outFile.WriteLine(originalPlaintext)

' Sample output:
' eyJhbGciOiJkaXIiLCJlbmMiOiJBMTI4R0NNIn0..20HX5Huc7f1nQC4pBUtiCQ.axFZIxtZy5j0ifJQUzGXLKIpsBuxJA.eBrOC-NrsreN6JeGuOPk1g
' original text: 
' Live long and prosper.

outFile.Close