VBScript

JWE using A256GCMKW

See more JSON Web Encryption (JWE) Examples

This example demonstrates creating a JCE with AES GCM key wrap. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

plaintext = "My text to enrypt"

set jwe = CreateObject("Chilkat.Jwe")

' First build the JWE Protected Header: 

'         {
'             "alg": "A256GCMKW",
'             "kid": "18ec08e1-bfa9-4d95-b205-2b4dd1d4321d",
'             "tag": "kfPduVQ3T3H6vnewt--ksw",
'             "iv": "KkYT0GX_2jHlfqN_",
'             "enc": "A128CBC-HS256"
'         }

set jweProtHdr = CreateObject("Chilkat.JsonObject")
success = jweProtHdr.AppendString("alg","A256GCMKW")
' kid is optional
success = jweProtHdr.AppendString("kid","18ec08e1-bfa9-4d95-b205-2b4dd1d4321d")
' tag is optional
success = jweProtHdr.AppendString("tag","kfPduVQ3T3H6vnewt--ksw")
success = jweProtHdr.AppendString("enc","A256GCM")
' the iv should be 16 random chars.
set prng = CreateObject("Chilkat.Prng")
success = jweProtHdr.AppendString("iv",prng.RandomString(16,1,1,1))
success = jwe.SetProtectedHeader(jweProtHdr)

outFile.WriteLine("JWE Protected Header: " & jweProtHdr.Emit())
outFile.WriteLine("--")

' Given that we have 256-bit AES, our key should be 32 bytes.
' The ascii string here is 32 bytes, therefore the 2nd arg is "ascii" to use these
' ascii chars directly as the key.
aesWrappingKey = "2baf4f730f5e4542b428593ef9cceb0e"
success = jwe.SetWrappingKey(0,aesWrappingKey,"ascii")

' Encrypt and return the JWE:
strJwe = jwe.Encrypt(plaintext,"utf-8")
If (jwe.LastMethodSuccess <> 1) Then
    outFile.WriteLine(jwe.LastErrorText)
    WScript.Quit
End If

' Show the JWE we just created:
outFile.WriteLine(strJwe)

' Decrypt the JWE that was just produced.
' 1) Load the JWE.
' 2) Set the AES wrapping key.
' 3) Decrypt.
set jwe2 = CreateObject("Chilkat.Jwe")
success = jwe2.LoadJwe(strJwe)
If (success <> 1) Then
    outFile.WriteLine(jwe2.LastErrorText)
    WScript.Quit
End If

' Set the AES wrap key.  Important to use "ascii"
success = jwe2.SetWrappingKey(0,aesWrappingKey,"ascii")

' Decrypt.
originalPlaintext = jwe2.Decrypt(0,"utf-8")
If (jwe2.LastMethodSuccess <> 1) Then
    outFile.WriteLine(jwe2.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("original text: ")
outFile.WriteLine(originalPlaintext)

outFile.Close