(VBScript) Insert JSON Object into another JSON Object

Demonstrates how to insert one JSON object into another. Effectively, the JSON object must be copied into the other..

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' Imagine we have two separate JSON objects.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonA = CreateObject("Chilkat.JsonObject")
success = jsonA.UpdateString("animal","zebra")
success = jsonA.UpdateString("colors[0]","white")
success = jsonA.UpdateString("colors[1]","black")

jsonA.EmitCompact = 0
outFile.WriteLine(jsonA.Emit())

' jsonA contains:

' {
'   "animal": "zebra",
'   "colors": [
'     "white",
'     "black"
'   ]
' }

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonB = CreateObject("Chilkat.JsonObject")
success = jsonB.UpdateString("type","mammal")
success = jsonB.UpdateBool("carnivore",0)

jsonB.EmitCompact = 0
outFile.WriteLine(jsonB.Emit())

' jsonB contains:

' {
'   "type": "mammal",
'   "carnivore": false
' }

' Let's say we want to insert jsonB into jsonA to get this:

' {
'   "animal": "zebra",
'   "info" " {
'       "type": "mammal",
'       "carnivore": false
' 	},
'   "colors": [
'     "white",
'     "black"
'   ]
' }

' First add an empty object at the desired location:
success = jsonA.AddObjectAt(1,"info")

' Get the JSON object at that location, and load the JSON..
' jsonInfo is a Chilkat.JsonObject
Set jsonInfo = jsonA.ObjectOf("info")
success = jsonInfo.Load(jsonB.Emit())

outFile.WriteLine(jsonA.Emit())

' The end result is this:

' {
'   "animal": "zebra",
'   "info": {
'     "type": "mammal",
'     "carnivore": false
'   },
'   "colors": [
'     "white",
'     "black"
'   ]
' }

outFile.Close