(VBScript) Get the Root of a JSON Document

Demonstrates how to get back to the JSON root object from anywhere in the JSON document. This example uses the following JSON document:

{
  "flower": "tulip",
  "abc":
    {
    "x": [
       { "a" : 1 },
       { "b1" : 100, "b2" : 200 },
       { "c" : 3 }
    ],
    "y": 200,
    "z": 200
    }
}

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set json = CreateObject("Chilkat_9_5_0.JsonObject")

jsonStr = "{""flower"": ""tulip"",""abc"":{""x"": [{ ""a"" : 1 },{ ""b1"" : 100, ""b2"" : 200 },{ ""c"" : 3 }],""y"": 200,""z"": 200}}"

success = json.Load(jsonStr)
If (success <> 1) Then
    outFile.WriteLine(json.LastErrorText)
    WScript.Quit
End If

' Get the "abc" object.
' abcObj is a Chilkat_9_5_0.JsonObject
Set abcObj = json.ObjectOf("abc")
If (json.LastMethodSuccess = 0) Then
    outFile.WriteLine("abc object not found.")
    WScript.Quit
End If

' Side note: The JSON of a sub-part of the document can be emitted from any JSON object:
abcObj.EmitCompact = 0
outFile.WriteLine(abcObj.Emit())

' Navigate to the "x" array
' xArray is a Chilkat_9_5_0.JsonArray
Set xArray = abcObj.ArrayOf("x")
' We'll skip the null check and assume it's non-null...

' Navigate to the 2nd object contained within the array.  This contains members b1 and b2
' bObj is a Chilkat_9_5_0.JsonObject
Set bObj = xArray.ObjectAt(1)
' We'll skip the null check and assume it's non-null...

' Show that we're at "b1/b2".
' The value of "b1" should be "200"
outFile.WriteLine("b2 = " & bObj.IntOf("b2"))

' Now go back to the JSON doc root:
' docRoot is a Chilkat_9_5_0.JsonObject
Set docRoot = bObj.GetDocRoot()
' We'll skip the null check and assume it's non-null...

' Pretty-print the JSON doc from the root to show that this is indeed the root.
docRoot.EmitCompact = 0
outFile.WriteLine(docRoot.Emit())


outFile.Close