VBScript

Loading and Parsing a JSON Array

See more JSON Examples

A JSON array is JSON that begins with "[" and ends with "]". For example, this is a JSON array that contains 3 JSON objects.

[{"name":"jack"},{"name":"john"},{"name":"joe"}]

A JSON object, however, is JSON that begins with "{" and ends with "}". For example, this JSON is an object that contains an array.

{"pets":[{"name":"jack"},{"name":"john"},{"name":"joe"}]}

This example shows how loading a JSON array is different than loading a JSON object. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

strJsonArray = "[{""name"":""jack""},{""name"":""john""},{""name"":""joe""}]"

strJsonObject = "{""pets"":[{""name"":""jack""},{""name"":""john""},{""name"":""joe""}]}"

' A JSON array must be loaded using JsonArray:
set jsonArray = CreateObject("Chilkat.JsonArray")
success = jsonArray.Load(strJsonArray)

' Examine the values:
i = 0
Do While i < jsonArray.Size
    ' jsonObj is a Chilkat.JsonObject
    Set jsonObj = jsonArray.ObjectAt(i)
    outFile.WriteLine(i & ": " & jsonObj.StringOf("name"))

    i = i + 1
Loop

' Output is:

' 	0: jack
' 	1: john
' 	2: joe

' A JSON object must be loaded using JsonObject
set jsonObject = CreateObject("Chilkat.JsonObject")
success = jsonObject.Load(strJsonObject)

' Examine the values:
i = 0
numPets = jsonObject.SizeOfArray("pets")
Do While i < numPets
    jsonObject.I = i
    outFile.WriteLine(i & ": " & jsonObject.StringOf("pets[i].name"))
    i = i + 1
Loop

' Output is:

' 	0: jack
' 	1: john
' 	2: joe

outFile.Close