(VBScript) Convert Java KeyStore to PKCS12 / PFX

Loads a Java keystore file and saves it as a PKCS12 / PFX. A Java keystore (JKS) can contain two types of entries: (1) trusted root certificates or (2) private keys + cert chains. Usually a JKS will contain all entries of one type or another (and thus a particular JKS serves one purpose or another; meaning that a JKS containing trusted roots is used as a source for verifying pre-trusted roots, and a JKS containing private keys (and cert chains) is used as a secure, encrypted store for private keys).

A PKCS12 / PFX typically contains one or more private keys, along with each private key's certificate chain. Therefore, it typically makes sense to only write the private key entries to a PKCS12 (and the associated certificate chains). If a JKS contains trusted root certificates, it makes more sense to conver it to a PEM file (such as the CA cert bundle in PEM format from mozilla.org).

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JavaKeyStore")
set jks = CreateObject("Chilkat.JavaKeyStore")

jksPassword = "myJksPassword"

' Load the Java keystore from a file.  The JKS file password is used
' to verify the keyed digest that is found at the very end of the keystore.
' It verifies that the keystore has not been modified.
success = jks.LoadFile(jksPassword,"/someDir/keyStore.jks")
If (success <> 1) Then
    outFile.WriteLine(jks.LastErrorText)
    WScript.Quit
End If

' To convert, we'll access the private key entries
' from the JKS, add each to the PKCS12, and then save the PKCS12.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Pfx")
set pkcs12 = CreateObject("Chilkat.Pfx")

numPrivateKeys = jks.NumPrivateKeys

' For each private key entry, get the private key and
' the associated certificate chain.
' Each private key is password protected.  Usually it is the same
' password as used for the keyed digest of the entire JKS.  
' However, this does not have to be.  The password is passed
' here to handle the possibility of each private key requiring
' a different password.
i = 0
Do While i < numPrivateKeys
    ' privKey is a Chilkat.PrivateKey
    Set privKey = jks.GetPrivateKey(jksPassword,i)
    outFile.WriteLine(jks.GetPrivateKeyAlias(i))
    ' certChain is a Chilkat.CertChain
    Set certChain = jks.GetCertChain(i)

    ' Add the private key and it's associated certificate chain to the PKCS12.
    success = pkcs12.AddPrivateKey(privKey,certChain)
    If (success <> 1) Then
        outFile.WriteLine(pkcs12.LastErrorText)

        WScript.Quit
    End If

    i = i + 1
Loop

' Save the PKCS12 / PFX to a file.
' The password can be the same as the JKS password, or something new.
' (With the PKCS12 format, there is a single password for the entire contents
' of the file.  With the JKS format, there is flexibility in allowing each private key
' to have it's own password.)
pkcs12Password = "myNewPassword"
success = pkcs12.ToFile(pkcs12Password,"/pkcs12_files/myPfx.p12")
If (success <> 1) Then
    outFile.WriteLine(pkcs12.LastErrorText)
Else
    outFile.WriteLine("Successfully saved to PKCS12 format.")
End If


outFile.Close