VBScript

Convert Java KeyStore to PEM

See more Java KeyStore (JKS) Examples

Loads a Java keystore file and saves the trusted certificate entries to a PEM file. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set jks = CreateObject("Chilkat.JavaKeyStore")

jksPassword = "myJksPassword"

' Load the Java keystore from a file.  The JKS file password is used
' to verify the keyed digest that is found at the very end of the keystore.
' It verifies that the keystore has not been modified.
success = jks.LoadFile(jksPassword,"/someDir/keyStore.jks")
If (success = 0) Then
    outFile.WriteLine(jks.LastErrorText)
    WScript.Quit
End If

' Open/create the output PEM file. 
' This example uses Chilkat's file access class for writing the output file.
' You may replace the file I/O lines of code with whatever is most convenient for you.
set fac = CreateObject("Chilkat.FileAccess")
success = fac.OpenForWrite("/pemFiles/caCerts.pem")
If (success = 0) Then
    outFile.WriteLine(fac.LastErrorText)
    WScript.Quit
End If

numCerts = jks.NumTrustedCerts

set cert = CreateObject("Chilkat.Cert")

' Iterate over the trusted certs, get the PEM for each,
' and append it to the output file.
i = 0
Do While i < numCerts
    success = jks.TrustedCertAt(i,cert)

    ' Get the certificate in PEM format.  
    pem = cert.ExportCertPem()

    ' Append the PEM string to the open file.
    success = fac.AppendText(pem,"utf-8")
    If (success <> 1) Then
        outFile.WriteLine(fac.LastErrorText)
        WScript.Quit
    End If

    i = i + 1
Loop

' Close the output file.
fac.FileClose 

outFile.WriteLine("Trusted certificates saved to PEM.")

outFile.Close