(VBScript) ITIDA Debug Signed JSON and HTTP POST

See more Egypt ITIDA Examples

Explains how to debug when problems are encountered with ITIDA canonicalization, signing, and posting to api.preprod.invoicing.eta.gov.eg.

The most common error response from the api.preprod.invoicing.eta.gov.eg server is:

ITIDA Signature Invalid Signature * 4043 4043:message-digest attribute value does not match the calculated value[message-digest attribute value does not match the calculated value]

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Crypt2")
set crypt = CreateObject("Chilkat.Crypt2")
crypt.VerboseLogging = 1

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Cert")
set cert = CreateObject("Chilkat.Cert")
cert.VerboseLogging = 1

' Set the smart card PIN, which will be needed for signing.
cert.SmartCardPin = "12345678"

' There are many ways to load the certificate.  
' This example was created for a customer using an ePass2003 USB token.
' Assuming the USB token is the only source of a hardware-based private key..
success = cert.LoadFromSmartcard("")
If (success <> 1) Then
    outFile.WriteLine(cert.LastErrorText)
    WScript.Quit
End If

' Tell the crypt class to use this cert.
success = crypt.SetSigningCert(cert)
If (success <> 1) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set cmsOptions = CreateObject("Chilkat.JsonObject")
' Setting "DigestData" causes OID 1.2.840.113549.1.7.5 (digestData) to be used.
success = cmsOptions.UpdateBool("DigestData",1)
success = cmsOptions.UpdateBool("OmitAlgorithmIdNull",1)

' Indicate that we are passing normal JSON and we want Chilkat do automatically
' do the ITIDA JSON canonicalization:
success = cmsOptions.UpdateBool("CanonicalizeITIDA",1)

crypt.CmsOptions = cmsOptions.Emit()

' The CadesEnabled property applies to all methods that create CMS/PKCS7 signatures. 
' To create a CAdES-BES signature, set this property equal to true. 
crypt.CadesEnabled = 1

crypt.HashAlgorithm = "sha256"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set jsonSigningAttrs = CreateObject("Chilkat.JsonObject")
success = jsonSigningAttrs.UpdateInt("contentType",1)
success = jsonSigningAttrs.UpdateInt("signingTime",1)
success = jsonSigningAttrs.UpdateInt("messageDigest",1)
success = jsonSigningAttrs.UpdateInt("signingCertificateV2",1)
crypt.SigningAttributes = jsonSigningAttrs.Emit()

' By default, all the certs in the chain of authentication are included in the signature.
' If desired, we can choose to only include the signing certificate:
crypt.IncludeCertChain = 0

' First, load the JSON file that is to be canonicalized and signed.
' The JSON file should look like this:
' NOTE: The JSON should not begin with "{ "documents" : [ ..."
' We want to send a single signed document like this:

'       {
'          "issuer":{
'             "address":{
'                "branchID":"0",
'                "country":"EG",
'                "regionCity":"Cairo",
'                "postalCode":"",
'                "buildingNumber":"0",
'                "street":"123rd Street",
'                "governate":"GOVERNATE"
'             },
'             "type":"B",
'             "id":"209999899",
'             "name":"Xyz SAE"
'          },
'          "receiver":{
'             "address":{
'                "country":"EG",
'                "regionCity":"CAIRO",
'                "postalCode":"11435",
'                "buildingNumber":"0",
'                "street":"Autostrad Road Abc",
'                "governate":"GOVERNATE"
'             },
'             "type":"B",
'             "id":"999999999",
'             "name":"XYZ EGYPT FOR TRADE"
'          },
'          "documentType":"I",
'          "documentTypeVersion":"1.0",
'          "dateTimeIssued":"2020-11-15T11:04:53Z",
'          "taxpayerActivityCode":"1073",
'          "internalID":"ZZZZ999",
'          "purchaseOrderReference":"2009199918",
'          "salesOrderReference":"",
'          "payment":{
'             "bankName":"",
'             "bankAddress":"",
'             "bankAccountNo":"",
'             "bankAccountIBAN":"",
'             "swiftCode":"",
'             "terms":""
'          },
'          "delivery":{
'             "approach":"",
'             "packaging":"",
'             "dateValidity":"",
'             "exportPort":"",
'             "countryOfOrigin":"EG",
'             "grossWeight":0,
'             "netWeight":0,
'             "terms":""
'          },
'          "invoiceLines":[
'             {
'                "description":"CDM Widget 48GX99X12BA",
'                "itemType":"GS1",
'                "itemCode":"7622213335056",
'                "unitType":"CS",
'                "quantity":1.00,
'                "unitValue":{
'                   "currencySold":"EGP",
'                   "amountEGP":588.67,
'                   "amountSold":0,
'                   "currencyExchangeRate":0
'                },
'                "salesTotal":588.67,
'                "total":603.97,
'                "valueDifference":0,
'                "totalTaxableFees":0,
'                "netTotal":529.8,
'                "itemsDiscount":0,
'                "discount":{
'                   "rate":10.00,
'                   "amount":58.87
'                },
'                "taxableItems":[
'                   {
'                      "taxType":"T1",
'                      "amount":74.17,
'                      "subType":"No sub",
'                      "rate":14.00
'                   }
'                ],
'                "internalCode":"9099994"
'             }
'          ],
'          "totalSales":588.67,
'          "totalSalesAmount":588.67,
'          "totalDiscountAmount":58.87,
'          "netAmount":529.80,
'          "taxTotals":[
'             {
'                "taxType":"T1",
'                "amount":74.17
'             }
'          ],
'          "extraDiscountAmount":0,
'          "totalItemsDiscountAmount":0,
'          "totalAmount":603.97,
'       }
' 

' Please include this JSON file as an attachment in your support email to Chilkat.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.LoadFile("c:/someDir/jsonToSignAndSend.json")
If (success = 0) Then
    outFile.WriteLine("Failed to load input JSON file.")
    WScript.Quit
End If

json.EmitCompact = 1
jsonToSign = json.Emit()

' Create the CAdES-BES signature.
crypt.EncodingMode = "base64"

' Make sure we sign the utf-8 byte representation of the JSON string
crypt.Charset = "utf-8"

' Turn on verbose logging.
crypt.VerboseLogging = 1

sigBase64 = crypt.SignStringENC(jsonToSign)
If (crypt.LastMethodSuccess = 0) Then
    outFile.WriteLine(crypt.LastErrorText)
    WScript.Quit
End If

' The LastErrorText property still contains information when the method succeeds.
' Send the contents of this LastErrorText as an attachment in your support email to Chilkat.
outFile.WriteLine(crypt.LastErrorText)

' Insert the base64 signature into the JSON to be sent
success = json.UpdateString("signatures[0].signatureType","I")
success = json.UpdateString("signatures[0].value",sigBase64)

' Wrap the JSON in  {"documents":[ ... ]}
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbToSend = CreateObject("Chilkat.StringBuilder")
success = sbToSend.Append("{""documents"":[")
success = sbToSend.Append(json.Emit())
success = sbToSend.Append("]}")

' ------------------------------------------------------------------------
' Submit the signed JSON to Chilkat's URL for simply echoing back the contents of the HTTP POST it receives:
' 
' We just want to see what actually gets sent.  To do this, we can send to https://www.chilkatsoft.com/echoPostBody.asp
' which will echo in the response that data and headers it received.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Http")
set http = CreateObject("Chilkat.Http")

' Also, set the SessionLogFilename property so we can see the exact bytes of the HTTP request sent from your end.
' Please include this session log file as an attachment in your support email to Chilkat.
http.SessionLogFilename = "c:/someDir/sessionLog.txt"

' resp is a Chilkat.HttpResponse
Set resp = http.PostJson2("https://www.chilkatsoft.com/echoPostBody.asp","application/json; charset=utf-8",sbToSend.GetAsString())
If (http.LastMethodSuccess = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

' Save the exact contents of Chilkat's response to a file.
' The server at https://www.chilkatsoft.com/echoPostBody.asp is simply echoing back the headers and POST body it received.
' Please include the responseBody.txt as an attachment in your support email to Chilkat.
success = resp.SaveBodyBinary("c:/someDir/responseBody.txt")

outFile.WriteLine("Response status code: " & resp.StatusCode)

' -------------------------------------------------
' In summary, please include the following in your support email to Chilkat
' 1. The original JSON file before signing and before canonicalization (i.e. c:/someDir/jsonToSignAndSend.json)
' 2. The contents of the LastErrorText for the successful call to SignStringENC.
' 3. The HTTP session log file (i.e. c:/someDir/sessionLog.txt)
' 4. The responseBody.txt file.

outFile.Close