(VBScript) Interfax -- Fax a Single Document

Demonstrates how to use the REST API to fax a single document using interfax.net. See Send fax for more information.

This example will send a POST with these potential query params:

POST /outbound/faxes?faxNumber={faxnumber}[&contact={string}&postponeTime={datetime}
&retriesToPerform={number}&csid={string}&pageHeader={string}&reference={string}
&replyAddress={email}&pageSize={a4|letter|legal|b4}&fitToPage={scale|noscale}
&pageOrientation={portrait|landscape}&resolution={fine|standard}&rendering={greyscale|bw}]

The HTTP POST request to be sent will look like this:

POST /outbound/faxes?faxNumber={faxnumber}&... HTTP/1.1
Host: rest.interfax.net
Authorization: Basic QWxhZGRpbjpvcGVuIHNlc2FtZQ==
Content-Type: application/msword
 
{binary content goes here}

Note: The Content-Type header field should match type type of document. For example, use "application/pdf" to fax a PDF. To find out what content-type header field values should be used, Google "MIME content type for XYZ" where XYZ describes the type of document. For example, one might Google "MIME content type for Excel xls", and the answer would be "application/vnd.ms-excel".

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = CreateObject("Chilkat.Rest")

' Use Basic Authentication.
' Use your InterFAX login and password.
success = rest.SetAuthBasic("INTERFAX_LOGIN","INTERFAX_PASSWORD")

' Connect to the Interfax REST server.
' Make sure TLS is used.  One should NEVER send a username+password using Basic authentication
' over a non-secure connection.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("rest.interfax.net",port,bTls,bAutoReconnect)

' Indicate the Content-Type of our upload.  
' We're faxing a PDF, so set the content-type to application/pdf.
success = rest.AddHeader("Content-Type","application/pdf")

' We can add an "Expect: 100-continue" header so that if the request is rejected
' by the server immediately after receiving the request header, it can respond
' and the client (Chilkat) can avoid sending the file data.
' (this is optional)
success = rest.AddHeader("Expect","100-continue")

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Stream")
set fileStream = CreateObject("Chilkat.Stream")

' The stream's source will be a file.
fileStream.SourceFile = "qa_data/pdf/fishing.pdf"

' Add query params.
' The fax number format is "+1-212-3456789"
success = rest.AddQueryParam("faxNumber","MY-FAX-NUMBER")
success = rest.AddQueryParam("pageSize","letter")
' Add any other desired query params ...

' The response is a 0-length "201 Created" response.
' Therefore the responseStr will be empty.
responseStr = rest.FullRequestStream("POST","/outbound/faxes",fileStream)
If (rest.LastMethodSuccess <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

If (rest.ResponseStatusCode <> 201) Then
    ' The response was not successful.
    ' We can examine the response code, header and status text:
    outFile.WriteLine("Response status code: " & rest.ResponseStatusCode)
    outFile.WriteLine("Response status text: " & rest.ResponseStatusText)
    outFile.WriteLine("Response header: " & rest.ResponseHeader)
    outFile.WriteLine("FAX failed.")
Else
    outFile.WriteLine("FAX sent.")
End If


outFile.Close