VBScript

Yahoo! IMAP (imap.mail.yahoo.com)

(from Wikipedia)

It is possible to get direct IMAP access without signing up for paid access nor using software like YPOPs! or FreePOPs. Yahoo! operates IMAP and secure IMAP servers (imap.mail.yahoo.com in particular), which are globally accessible. However they require a specific, non-standard IMAP command to be sent before login is done, namely: “ID ("GUID" "1")”.

This example demonstrates sending the non-standard IMAP command after connecting but before login. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat.Imap")

' Connect to they Yahoo! IMAP server.
imap.Port = 993
imap.Ssl = 1
success = imap.Connect("imap.mail.yahoo.com")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Send the non-standard ID command...

rawResponse = imap.SendRawCommand("ID (""GUID"" ""1"")")
If (imap.LastMethodSuccess <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Login Success!")

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Continue with whatever you wish to do...
' (see other examples..)

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close