VBScript

Determine the Number of Unseen Email Messages

Demonstrates how to determine how many unseen messages exist in an email account on an IMAP server. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Login
success = imap.Login("***","***")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' After selecting the mailbox. the total number of emails
' is immediately available:
totalNum = imap.NumMessages
outFile.WriteLine("Num messages = " & totalNum)

' To determine the number of unseen messages, a call
' to Search is required, which returns the set of UIDs
' of all unseen messages.

' We can choose to fetch UIDs or sequence numbers.
fetchUids = 1
set messageSet = CreateObject("Chilkat.MessageSet")
success = imap.QueryMbx("UNSEEN",fetchUids,messageSet)
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

numUnseen = messageSet.Count
outFile.WriteLine(numUnseen)

outFile.WriteLine("UIDs ----")

' Display the UIDs
i = 0
Do While i < messageSet.Count
    outFile.WriteLine(messageSet.GetId(i))
    i = i + 1
Loop

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close