(VBScript) Mark IMAP Email as Read/Unread (Seen/Unseen)

Demonstrates how to mark emails as read or unread.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Imap")
set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.someMailServer.com")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Set PeekMode so that downloaded messages are not
' automatically marked as seen.
imap.PeekMode = 1

' The NumMessages property contains the number of messages 
' in the currently selected mailbox.
numMsgs = imap.NumMessages
If (numMsgs = 0) Then
    WScript.Quit
End If

For i = 1 To numMsgs
    ' Download each email by sequence number (not UID)

    ' email is a Chilkat.Email
    Set email = imap.FetchSingle(i,0)
    If (imap.LastMethodSuccess = 0) Then
        outFile.WriteLine(imap.LastErrorText)
        WScript.Quit
    End If

    ' If desired, mark the email as SEEN.  There are two
    ' ways to do it:

    ' 1) Set the flag directly by using the sequence number
    ' Indicate that we are passing a sequence number and
    ' not a UID:
    bIsUid = 0
    ' Set the SEEN flag = 1 to mark the email as SEEN,
    ' or set it to 0 to mark it as not-seen.
    success = imap.SetFlag(i,bIsUid,"SEEN",1)
    If (success <> 1) Then
        outFile.WriteLine(imap.LastErrorText)
        WScript.Quit
    End If

    ' 2) Alternatively, we can use the email object.
    ' When an email is downloaded from the IMAP server
    ' Chilkat will add a "ckx-imap-uid" header to the email.
    ' This makes it possible to know the UID associated with
    ' the email.  (This is not the sequence number, which may change
    ' from session to session, but the UID which does not change.
    ' The SetMailFlag method is identical to SetFlag, except
    ' it gets the UID from the ckx-imap-uid header.
    ' For example:
    success = imap.SetMailFlag(email,"SEEN",1)
    If (success <> 1) Then
        outFile.WriteLine(imap.LastErrorText)
        WScript.Quit
    End If

Next

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close