(VBScript) IMAP Get Quota Root

Sends the GETQUOTAROOT command to the IMAP server to get the quota root for a given mailbox. This also provides quota information for the given mailbox.

The GetQuotaRoot method is available in Chilkat starting at v9.5.0.58, and is only available for IMAP servers that support the QUOTA extension.

The information is returned in JSON format. This example demonstrates how to parse the JSON to get the desired information.

Typically, the quota root for the Inbox is the empty string.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Imap")
set imap = CreateObject("Chilkat.Imap")

' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("MY-IMAP-DOMAIN")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Authenticate
success = imap.Login("MY-IMAP-LOGIN","MY-IMAP-PASSWORD")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' First check to see if the IMAP server supports the QUOTA extension.
caps = imap.Capability()
If (imap.LastMethodSuccess <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

If (imap.HasCapability("QUOTA",caps) <> 1) Then
    outFile.WriteLine("IMAP server does not support the QUOTA extension.")
    WScript.Quit
End If

jsonStr = imap.GetQuotaRoot("Inbox")
If (imap.LastMethodSuccess <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' The JSON string will look something like this:
' {"QUOTAROOT":{"mailbox":"Inbox","root":""},"QUOTA":{"root":"","resource":"STORAGE","used":22216,"max":15728640}}
outFile.WriteLine(jsonStr)

' This is easy to parse...
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = CreateObject("Chilkat.JsonObject")
success = json.Load(jsonStr)

' Get the quota root for Inbox, which is an empty string in the case above.
quotaRoot = json.StringOf("QUOTAROOT.root")
outFile.WriteLine("Quota Root for Inbox: [" & quotaRoot & "]")

' Now get the resource name (which can be STORAGE or MESSAGE) and the used/max values.
' Most servers have STORAGE quotas, which are for total capacity.  For example, GMail's
' STORAGE quota is 15GB (at the time of writing this example).
' A MESSAGE quota sets a limit on the number of messages.
resourceName = json.StringOf("QUOTA.resource")
quotaUsed = json.IntOf("QUOTA.used")
quotaMax = json.IntOf("QUOTA.max")

outFile.WriteLine("Resource: " & resourceName)
outFile.WriteLine("Quota Used (in KB): " & quotaUsed)
outFile.WriteLine("Quota Max (in KB): " & quotaMax)

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close