VBScript

Fetch Inbox Email Headers

Downloads the headers of all emails in the Inbox and shows some information about each, such as From, Subject, and whether the email has been seen (already read) or not. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Login
success = imap.Login("myLogin","myPassword")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Normally, when an email is downloaded, its "Seen" flag is automatically set.
' We don't want our program to be interfering with the "Seen" flags.
' To do this, set the PeekMode to 1.
imap.PeekMode = 1

' After selecting the mailbox, the NumMessages property
' will contain the number of emails in the mailbox.
' When sequence numbers (not UIDs) are used to reference emails,
' they range from 1 to N, where N is the number of messages in the mailbox.
' This example will download the headers by sequence numbers.
count = imap.NumMessages

set bundle = CreateObject("Chilkat.EmailBundle")
success = imap.FetchRange(1,1,count,bundle)
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

If (bundle.MessageCount = 0) Then
    outFile.WriteLine("No messages in Inbox.")
    WScript.Quit
End If

' Loop over the email headers.  
set emailHeader = CreateObject("Chilkat.Email")
i = 0
Do While i < bundle.MessageCount

    success = bundle.EmailAt(i,emailHeader)

    outFile.WriteLine(emailHeader.From)
    outFile.WriteLine(emailHeader.Subject)

    ' Get the "Seen" flag.
    ' When an email is fetched from the IMAP server, the email flags are stored
    ' within the email in the "ckx-imap-flags" header.
    ' The call to GetMailFlag is simply getting the information from the email header.
    ' (it is not communicating with the IMAP server to get this information, because
    ' the information was obtained when downloading the headers)
    seenFlag = imap.GetMailFlag(emailHeader,"Seen")
    If (seenFlag = 1) Then
        outFile.WriteLine("This email has been read (already seen)")
    Else
        outFile.WriteLine("This email has not yet been read (it is not yet seen)")
    End If

    ' We can also look directly at the "ckx-imap-flags" header:
    outFile.WriteLine("ckx-imap-flags: " & emailHeader.GetHeaderField("ckx-imap-flags"))

    outFile.WriteLine("--")

    i = i + 1
Loop

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close