(VBScript) Download IMAP Message Set using FetchBundle

Demonstrates how to read IMAP emails using the FetchBundle method.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Imap")
set imap = CreateObject("Chilkat.Imap")

' Connect using TLS.
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Authenticate
success = imap.Login("email_account_login","email_account_password")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Search for messages with the word "test" in the subject.
fetchUids = 1
' messageSet is a Chilkat.MessageSet
Set messageSet = imap.Search("Subject test",fetchUids)
If (imap.LastMethodSuccess <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Download the messages in a single call to FetchBundle.
' 
' This only makes sense if the number of emails to be downloaded is not too large.  
' For example, you wouldn't want to download 10000 emails in a single call to FetchBundle.
' Why? For two reasons:  (1) It could potentially cause an out-of-memory condition, and 
' (2) it would take an extremely large amount of time.  The longer the amount of time,
' the greater the likelihood of some kind of external networking or server problem occuring,
' and if it happens, then you would need to re-download everything from the beginning again.
' For large numbers of emails, it's better to loop over the emails in the message set
' and download/process one at a time as shown here: Download IMAP Messages One at a Time
' Downloading one message at a time makes it possible to resume the downloads rather than restart the entire operation all over again.

' If the message set is reasonable in size, you can download all at once using FetchBundle:

outFile.WriteLine("Number of messages = " & messageSet.Count)

' bundle is a Chilkat.EmailBundle
Set bundle = imap.FetchBundle(messageSet)
If (imap.LastMethodSuccess = 0) Then

    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Display the Subject and From of each email.
i = 0
numEmails = bundle.MessageCount
Do While i < numEmails
    ' email is a Chilkat.Email
    Set email = bundle.GetEmail(i)

    outFile.WriteLine(email.GetHeaderField("Date"))
    outFile.WriteLine(email.Subject)
    outFile.WriteLine(email.From)
    outFile.WriteLine("--")

    i = i + 1
Loop


outFile.Close