(VBScript) IMAP Download and Verify Signed (S/MIME) Email

Demonstrates how to download and verify digitally signed S/MIME email.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

success = imap.Login("myLogin","myPassword")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' We can choose to fetch UIDs or sequence numbers.
fetchUids = 1

' Get the message IDs of all the emails in the mailbox
set messageSet = CreateObject("Chilkat.MessageSet")
success = imap.QueryMbx("ALL",fetchUids,messageSet)
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

set email = CreateObject("Chilkat.Email")
set cert = CreateObject("Chilkat.Cert")

i = 0
Do While i < messageSet.Count

    uid = messageSet.GetId(i)
    outFile.WriteLine("uid: " & uid)

    success = imap.FetchEmail(0,uid,1,email)
    If (success = 0) Then
        outFile.WriteLine(imap.LastErrorText)
        WScript.Quit
    End If

    ' The security layers of signed and/or encrypted emails
    ' are automatically "unwrapped" when loaded into
    ' a Chilkat email object.
    ' An application only needs to check to see if an email
    ' was received signed or encrypted, and then examine
    ' the success/failure.  For example:
    If (email.ReceivedSigned = 1) Then

        outFile.WriteLine("This email was signed.")

        ' Check to see if the signatures were verified.
        If (email.SignaturesValid = 1) Then
            outFile.WriteLine("Digital signature(s) verified.")
            outFile.WriteLine("Signer: " & email.SignedBy)

            ' Get the certificate used for signing.
            success = email.LastSignerCert(0,cert)

            If (success = 0) Then
                outFile.WriteLine("Failed to get signing certificate object.")
            Else
                outFile.WriteLine("Signing cert: " & cert.SubjectCN)
            End If

        Else
            outFile.WriteLine("Digital signature verification failed.")
        End If

    End If

    i = i + 1
Loop

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close