(VBScript) Download MIME Source of Emails in IMAP Mailbox

Demonstrates how to download the MIME source for emails on an IMAP server.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Login
success = imap.Login("myLogin","myPassword")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' The NumMessages property contains the number of messages in the selected mailbox.
numMessages = imap.NumMessages
If (numMessages = 0) Then
    outFile.WriteLine("No messages exist in the Inbox.")
    WScript.Quit
End If

set sbMime = CreateObject("Chilkat.StringBuilder")

For seqNum = 1 To numMessages
    sbMime.Clear 
    success = imap.FetchSingleAsMimeSb(seqNum,0,sbMime)
    If (success = 0) Then
        outFile.WriteLine(imap.LastErrorText)
        WScript.Quit
    End If

    ' The MIME source of the downloaded email is contained in sbMime.
Next

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close