VBScript

Delete Email Individually (One at a time) from an IMAP Mailbox

Downloads email from an IMAP mailbox and deletes emails individually (one by one). VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Login
success = imap.Login("myLogin","myPassword")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' We can choose to fetch UIDs or sequence numbers.
fetchUids = 1

' Get the message IDs of all the emails in the mailbox
set messageSet = CreateObject("Chilkat.MessageSet")
success = imap.QueryMbx("ALL",fetchUids,messageSet)
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Fetch the emails into a bundle object:
set bundle = CreateObject("Chilkat.EmailBundle")
headersOnly = 0
success = imap.FetchMsgSet(headersOnly,messageSet,bundle)
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' To mark a complete set of emails for deletion, call SetFlags:
success = imap.SetFlags(messageSet,"Deleted",1)
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Messages can also be marked for deletion individually:
' Loop over the bundle and mark each message for deletion.
set email = CreateObject("Chilkat.Email")
i = 0
numEmails = bundle.MessageCount
Do While i < numEmails
    success = bundle.EmailAt(i,email)

    outFile.WriteLine(email.From)
    outFile.WriteLine(email.Subject)

    ' To delete this email, set the "Deleted" flag to 1.
    ' The email is not actually deleted until Expunge or
    ' ExpungeAndClose is called.
    success = imap.SetMailFlag(email,"Deleted",1)
    If (success = 0) Then
        outFile.WriteLine(imap.LastErrorText)
        WScript.Quit
    End If

    outFile.WriteLine("--")

    i = i + 1
Loop

success = imap.ExpungeAndClose()
If (success = 0) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close