VBScript

How to Copy IMAP Mail to another IMAP Server

Demonstrates how to copy the entire contents of an IMAP mailbox to another IMAP server. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imapSrc = CreateObject("Chilkat.Imap")

' Connect to our source IMAP server.
success = imapSrc.Connect("imap.example.com")
If (success = 0) Then
    outFile.WriteLine(imapSrc.LastErrorText)
    WScript.Quit
End If

' Login to the source IMAP server
success = imapSrc.Login("admin@chilkatsoft.com","myPassword")
If (success = 0) Then
    outFile.WriteLine(imapSrc.LastErrorText)
    WScript.Quit
End If

set imapDest = CreateObject("Chilkat.Imap")

' Connect to our destination IMAP server.
success = imapDest.Connect("mail.example-code.com")
If (success = 0) Then
    outFile.WriteLine(imapDest.LastErrorText)
    WScript.Quit
End If

' Login to the destination IMAP server
success = imapDest.Login("myLogin","myPassword")
If (success = 0) Then
    outFile.WriteLine(imapDest.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox on the source IMAP server
success = imapSrc.SelectMailbox("Inbox")
If (success = 0) Then
    outFile.WriteLine(imapSrc.LastErrorText)
    WScript.Quit
End If

' After selecting a mailbox, the NumMessages property will
' be updated to reflect the total number of emails in the mailbox:
outFile.WriteLine(imapSrc.NumMessages)

' The emails in the mailbox will always have sequence numbers
' ranging from 1 to NumMessages.

' This example will copy the first 10 messages using sequence numbers
set sbMime = CreateObject("Chilkat.StringBuilder")

For seqNum = 1 To 10
    sbMime.Clear 
    success = imapSrc.FetchSingleAsMimeSb(seqNum,0,sbMime)
    If (success = 0) Then
        outFile.WriteLine(imapSrc.LastErrorText)
        WScript.Quit
    End If

    success = imapDest.AppendMimeWithFlagsSb("Inbox",sbMime,0,0,0,0)
    If (success = 0) Then
        outFile.WriteLine(imapDest.LastErrorText)
        WScript.Quit
    End If

Next

' Disconnect from the IMAP servers.
success = imapSrc.Disconnect()
success = imapDest.Disconnect()

outFile.Close