(VBScript) IMAP Copy Email from Selected Folder to Another Folder

Copies an email from the selected mailbox (folder) to another mailbox (folder).

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' This example copies an email from one mailbox to another.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Imap")
set imap = CreateObject("Chilkat.Imap")

' Turn on session logging for debugging.
imap.KeepSessionLog = 1

' Connect using TLS.
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Authenticate
success = imap.Login("email_account_login","email_account_password")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Search for messages having "Test email" in the subject.
fetchUids = 1
' messageSet is a Chilkat.MessageSet
Set messageSet = imap.Search("SUBJECT ""Test email""",fetchUids)
If (imap.LastMethodSuccess <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Assuming we have 1 or more messages in the set, copy the 1st one to the folder "Inbox.testFolder"
If (messageSet.Count > 0) Then
    success = imap.Copy(messageSet.GetId(0),messageSet.HasUids,"Inbox/testFolder")
    If (success <> 1) Then
        outFile.WriteLine(imap.LastErrorText)
    End If

End If

outFile.WriteLine(imap.SessionLog)

outFile.WriteLine("OK")

' Sample sessiong log:

' ----INFO----
' Connecting to IMAP server at outlook.office365.com:993
' ----IMAP RESPONSE----
' * OK The Microsoft Exchange IMAP4 service is ready. [QgBMADAAUABSADAAMQAwADIAQwBBADAAMAA3ADAALgBwAHIAbwBkAC4AZQB4AGMAaABhAG4AZwBlAGwAYQBiAHMALgBjAG8AbQA=]
' ----IMAP REQUEST----
' aaab LOGIN "chilkat@live.com"
' ----IMAP RESPONSE----
' aaab OK LOGIN completed.
' ----IMAP REQUEST----
' aaac SELECT "Inbox"
' ----IMAP RESPONSE----
' * 28 EXISTS
' * 0 RECENT
' * FLAGS (\Seen \Answered \Flagged \Deleted \Draft $MDNSent)
' * OK [PERMANENTFLAGS (\Seen \Answered \Flagged \Deleted \Draft $MDNSent)] Permanent flags
' * OK [UNSEEN 23] Is the first unseen message
' * OK [UIDVALIDITY 14] UIDVALIDITY value
' * OK [UIDNEXT 6416] The next unique identifier value
' aaac OK [READ-WRITE] SELECT completed.
' ----IMAP REQUEST----
' aaad UID SEARCH SUBJECT "Test email"
' ----IMAP RESPONSE----
' * SEARCH 6414
' aaad OK SEARCH completed.
' ----IMAP REQUEST----
' aaae UID COPY 6414 "Inbox/testFolder"
' ----IMAP RESPONSE----
' aaae OK [COPYUID 180 6414 1] COPY completed.
' 
' OK

outFile.Close