VBScript

IMAP Capability

Demonstrates how to send the CAPABILITY command to request a listing of capabilities that the IMAP server supports. A capability name which begins with "AUTH=" indicates that the server supports that particular authentication mechanism. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat.Imap")

' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("MY-IMAP-DOMAIN")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Authenticate
success = imap.Login("MY-IMAP-LOGIN","MY-IMAP-PASSWORD")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Get the list of capabilities:
caps = imap.Capability()
outFile.WriteLine("Capabilities: " & caps)

' Here is an example of the string returned:
' * CAPABILITY IMAP4rev1 UNSELECT IDLE NAMESPACE QUOTA ID XLIST CHILDREN X-GM-EXT-1 
' UIDPLUS COMPRESS=DEFLATE ENABLE MOVE CONDSTORE ESEARCH UTF8=ACCEPT APPENDLIMIT=35882577
' LIST-EXTENDED LIST-STATUS

' Chilkat v9.5.0.58 introduces the HasCapability method to
' check to see if a particular capability exists:
If (imap.HasCapability("QUOTA",caps) = 1) Then
    outFile.WriteLine("IMAP server supports the QUOTA extension.")
End If

If (imap.HasCapability("IDLE",caps) = 1) Then
    outFile.WriteLine("IMAP server supports IDLE.")
End If

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close