VBScript

Upload (Append) Email to an IMAP Mailbox and get the UID of the Appended Email

Upload / append an email to an IMAP mailbox and get the UID of the appended email. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set imap = CreateObject("Chilkat.Imap")

' Connect to an IMAP server.
' Use TLS
imap.Ssl = 1
imap.Port = 993
success = imap.Connect("imap.example.com")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' Check the capabilities of the IMAP server.
cap = imap.Capability()
outFile.WriteLine("IMAP capabilities: " & cap)

' If the capabilities string contains the substring "UIDPLUS", then 
' the UID of the appended email will be available in the AppendUid property (see below).

' For example, the GMail IMAP server has these capabilities (at this current time)
' * CAPABILITY IMAP4rev1 UNSELECT IDLE NAMESPACE QUOTA ID XLIST CHILDREN 
' X-GM-EXT-1 UIDPLUS COMPRESS=DEFLATE ENABLE MOVE CONDSTORE ESEARCH UTF8=ACCEPT 
' APPENDLIMIT=35882577 LIST-EXTENDED LIST-STATUS

set email = CreateObject("Chilkat.Email")

' Load the email from a .eml file.
success = email.LoadEml("myEmail.eml")
If (success <> 1) Then
    outFile.WriteLine(email.LastErrorText)
    WScript.Quit
End If

success = imap.AppendMail("Inbox",email)
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

' If the IMAP server supports the UIDPLUS extension, then the 
' imap.AppendUid will contain the UID of the appended email.
' Otherwise AppendUid will be 0.
outFile.WriteLine("UID of appended email: " & imap.AppendUid)

' If the IMAP server does NOT have UIDPLUS, then a program can 
' first select the mailbox, get the value of the UidNext property,
' and then append.  The appended email SHOULD have a UID equal to 
' the UidNext that was obtained just prior to appending (assuming no other
' program is simultaneously appending an email to the same mailbox).

' Note: It is not required to select a mailbox to append.  The select is only
' done for the purpose of obtaining the UIDNEXT value.
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

uidNext = imap.UidNext

success = imap.AppendMail("Inbox",email)
If (success <> 1) Then
    outFile.WriteLine(imap.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("The UID of the appended email SHOULD be " & uidNext)

outFile.WriteLine("Email uploaded to Inbox!")

' Disconnect from the IMAP server.
success = imap.Disconnect()

outFile.Close