VBScript

IKOF Generation Code for Montenegro Fiscalization Service

See more _Miscellaneous_ Examples

Demonstrates computing the IKOF MD5 summary value as described in section 4.3 of this document: https://poreskauprava.gov.me/ResourceManager/FileDownload.aspx?rId=416042&rType=2 VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

concatenatedParams = "12345678|2019-06-12T17:05:43+02:00|9952|bb123bb1231|cc123cc1231|ss123ss123|199.01"

' Get the private key from a pfx file.
set pfx = CreateObject("Chilkat.Pfx")
success = pfx.LoadPfxFile("qa_data/pfx/cert_test123.pfx","test123")
If (success = 0) Then
    outFile.WriteLine(pfx.LastErrorText)
    WScript.Quit
End If

set privKey = CreateObject("Chilkat.PrivateKey")
success = pfx.PrivateKeyAt(0,privKey)
If (success = 0) Then
    outFile.WriteLine(pfx.LastErrorText)
    WScript.Quit
End If

' Create IIC signature according to RSASSA-PKCS-v1_5 using SHA256
set rsa = CreateObject("Chilkat.Rsa")
success = rsa.UsePrivateKey(privKey)
If (success = 0) Then
    outFile.WriteLine(rsa.LastErrorText)
    WScript.Quit
End If

' PKCS-v1_5 is used by default.
rsa.EncodingMode = "hex"
rsa.Charset = "utf-8"
hexSig = rsa.SignStringENC(concatenatedParams,"sha256")

outFile.WriteLine("Signature value result is: " & hexSig)

' Compute the MD5 hash of the bytes.
set crypt = CreateObject("Chilkat.Crypt2")
crypt.EncodingMode = "hex"
crypt.HashAlgorithm = "md5"
set bd = CreateObject("Chilkat.BinData")
success = bd.AppendEncoded(hexSig,"hex")
md5_summary = crypt.HashBdENC(bd)

outFile.WriteLine("MD5 summary value is: " & md5_summary)

outFile.Close